/* Copyright (c) Oracle Corporation 1994.  All Rights Reserved */

/*****************************************************************************
  NAME
    graph30.vrf - V3 analysis/product configuration script for Graphics 3.0

  DESCRIPTION
    This script checks dependencies and environment settings for the
    installation of the Graphics 3.0 package

  MODIFIED    MM/DD/YY   Reason
    rbchen    01/22/97   Prompt user to install Demos and Add-ons
   rbansal    03/27/96   Created from graph25.vrf
******************************************************************************/

{
    SHARED_ORACLE_COMPLIANT = TRUE;

    {doit = execute("%installer_home%%dir_separator%%operating_system%.vrf");}
    [
        'UNBOUND_VARIABLE:
        {
            required_version = product_version(instver_product);
            temp             = explode(required_version, ".");
            required_version = implode(list(first(temp),first(rest(temp)),
                                            first(rest(rest(temp))),
                                            first(rest(rest(rest(temp))))), ".");
            signal('FAILURE, instantiate(nls("instver_too_early1",
                                             "The version of the Installer currently running is %%installer_version%%. The installation you have chosen requires version %%required_version%% or later. Please run version %%required_version%% or later in order to perform this installation.")));
        }
    ]                                                                   /* This FAILURE will cause 3.0.x.x installer to exit gracefully. */

    /******************************************************************************************************
    START MAIN LOGIC
    ******************************************************************************************************/
    if (doit)
    {
        /****************************************************************
        Display the generic "Welcome to Oracle Developer"
        billboard if not already displayed, and if Developer release
        *****************************************************************/
        if(exists("%installer_home%%dir_separator%d2bb_01.bmp"))
        {
            if(DEVELOPER2000_RELEASE)
            {
                if(not(DEV2K_BB01))
                {
                    DEV2K_BB01 = TRUE;
                    ui_graphics("%installer_home%%dir_separator%d2bb_01.bmp");
                }
            }
        }
        /****************************************************************/

        /*****************************
        Set the VRF-INS script ratchet
        ******************************/
        vrf_ratchet = "6.0.8.13.0";

         main_product_version = "6.0.5.33.0";
         /***************************
         Check Installed Version
         ***************************/
         if(registered(product_name(current_product)))
         {
              check_installed_version = registry_version(registration(product_name(current_product)));
              if(earlier_version(check_installed_version, main_product_version))
              {
                   information_dialog(instantiate(product_upgrade_required),
                                      instantiate(product_upgrade_contents),
                                      instantiate(product_upgrade_help));
                   refresh_map_file = FALSE;
                   doit = FALSE;
                   return(0);
              }
          }
          else
          {
                information_dialog(instantiate(main_product_required),
                                   instantiate(main_product_contents),
                                   instantiate(main_product_help));
                 refresh_map_file = FALSE;
                 doit = FALSE;
                 signal('FAILURE, instantiate(halt_installation));
          }
        /************************************************
        Create a label with the product name, and version
        *************************************************/
        EXECUTE_SCRIPT = "CREATE_LABEL";
        execute("%installer_home%%dir_separator%d2kr2vrf.usr");
            /************************************************/

        /***********************
        Create Dependencies List
        ************************/
        dependency_list     = list(w32tutil60, w32rsf80);  /*for referencing*/ /* added rsf for patch-6*/
        verify_dependency_list     = list(w32tutil60, w32gui60, w32rsf80);  /*to verify for installation*/ /*rsf added for patch-6*/
        install_dependency_list = list();


       if(not(registered("w32brqry60")))
        {
             information_dialog(instantiate(brqry_product_required),
                                instantiate(brqry_product_contents),
                                instantiate(brqry_product_help));
             signal('FAILURE, instantiate(halt_installation));  
        }

       if(not(registered("w32ssf60")))/* Added newly */
        {
             information_dialog(instantiate(ssf_product_required),
                                instantiate(ssf_product_contents),
                                instantiate(ssf_product_help));
             signal('FAILURE, instantiate(halt_installation));  
        }

       /*if(not(registered("w32gui60")))
        {
             information_dialog(instantiate(gui_product_required),
                                instantiate(gui_product_contents),
                                instantiate(gui_product_help));
             signal('FAILURE, instantiate(halt_installation));  
        }*/

        /***********************/

        /**********************************************************************
        parent_in_control = TRUE ==> the complete product needs to be installed
        parent_in_control = FALSE ==> PARENT called by one of the components
        ***********************************************************************/
        parent_in_control = TRUE;
        if(not(member(selected_products, current_product)))
        {
            child_products = all_child_products(current_product);
            while(not(empty(child_products)))
            {
                next_child = first(child_products);
                child_products = rest(child_products);
                if(member(products_for_installation, next_child))
                    parent_in_control = FALSE;                            /* PARENT called by one of the components */
            }
        }
        /**********************************************************************/


        /**************************
        Determine installation path
        ***************************/
        install_variable = "GRAPHICS60";
        default_home     = "%oracle_home%%dir_separator%GRAPH60";
        section_heading  = product_filename(current_product);
        GRAPHICS60       = execute("%installer_home%%dir_separator%instloc.usr");
        /**************************/

        /*************************
         Initialize total size of files
        **************************/
        total_sum = 0;

        /***********************************************
        If PARENT is explicitly called for installation,
        verify all the component products
        ************************************************/
        if(parent_in_control)
        {
            EXECUTE_SCRIPT = "VERIFY_COMPONENTS";
            total_sum = execute("%installer_home%%dir_separator%d2kr2vrf.usr");
        }
        else
        {
            child_products = all_child_products(current_product);
            selected_components_list = list();
            size_component = 0;

            while(not(empty(child_products)))
            {
                next_child = first(child_products);
                if(member(selected_products, next_child))
                {
                    if(not(member(products_for_installation, next_child)))
                    {
                        size_component = verify(next_child);
                        if(size_component != 0)
                        {
                            add(selected_components_list, next_child);
                            total_sum = total_sum + size_component;
                        }
                    }
                }
                child_products = rest(child_products);
            }
        }
        /***********************************************/

        /******************
        Verify Dependencies
        *******************/
        EXECUTE_SCRIPT = "VERIFY_DEPENDENCIES";
        total_sum = total_sum + execute("%installer_home%%dir_separator%d2kr2vrf.usr");
        /******************/

        /******************************************************************/


        total_sum = total_sum + sum(deinst);

        return(total_sum);
        /***************************************************************************/
    }
    else
    {
        refresh_map_file = FALSE;
        return(0);
    }
}