/* Copyright (c) Oracle Corporation 1994.  All Rights Reserved */

/*****************************************************************************
  NAME
    gdes60.vrf - V3 analysis/product configuration script for
                 Graphics 6.0 Designer

  DESCRIPTION
    This script checks dependencies and environment settings for the
    installation of Graphics 6.0 Designer.

  MODIFIED   MM/DD/YY   REASON
   pgupta    10/20/97   Created
*****************************************************************************/

{
    SHARED_ORACLE_COMPLIANT = TRUE;

    {doit = execute("%installer_home%%dir_separator%%operating_system%.vrf");}
    [
        'UNBOUND_VARIABLE:
        {
            required_version = product_version(instver_product);
            temp             = explode(required_version, ".");
            required_version = implode(list(first(temp),first(rest(temp)),
                                            first(rest(rest(temp))),
                                            first(rest(rest(rest(temp))))), ".");
            signal('FAILURE, instantiate(nls("instver_too_early1",
                                             "The version of the Installer currently running is %%installer_version%%. The installation you have chosen requires version %%required_version%% or later. Please run version %%required_version%% or later in order to perform this installation.")));
        }
    ]                                                                   /* This FAILURE will cause 3.0.x.x installer to exit gracefully. */

    /*****************************************************************************************************
    START MAIN LOGIC
    ******************************************************************************************************/
    if (doit)
    {
        /****************************************************************
        Display the generic "Welcome to Oracle Developer"
        billboard if not already displayed, and if Developer release
        *****************************************************************/
        if(exists("%installer_home%%dir_separator%d2bb_01.bmp"))
        {
            if(DEVELOPER2000_RELEASE)
            {
                if(not(DEV2K_BB01))
                {
                    DEV2K_BB01 = TRUE;
                    ui_graphics("%installer_home%%dir_separator%d2bb_01.bmp");
                }
            }
        }
        /****************************************************************/

        /*****************************
        Set the VRF-INS script ratchet
        ******************************/
        vrf_ratchet = "6.0.8.13.0";

         main_product_version = "6.0.5.33.0";
         /***************************
         Check Installed Version
         ***************************/
         if(registered(product_name(current_product)))
         {
              check_installed_version = registry_version(registration(product_name(current_product)));
              if(earlier_version(check_installed_version, main_product_version))
              {
                   information_dialog(instantiate(product_upgrade_required),
                                      instantiate(product_upgrade_contents),
                                      instantiate(product_upgrade_help));
                   refresh_map_file = FALSE;
                   doit = FALSE;
                   return(0);
              }
          }
          else
          {
                information_dialog(instantiate(main_product_required),
                                   instantiate(main_product_contents),
                                   instantiate(main_product_help));
                 refresh_map_file = FALSE;
                 doit = FALSE;
                 signal('FAILURE, instantiate(halt_installation));
          }
        /************************************************
        Create a label with the product name, and version
        *************************************************/
        EXECUTE_SCRIPT = "CREATE_LABEL";
        execute("%installer_home%%dir_separator%d2kr2vrf.usr");
        /************************************************/

        /******************************************************************
        child_in_control = TRUE ==> component product called explicitly
        child_in_control = FALSE ==> component product called by the PARENT
        *******************************************************************/
        child_in_control = TRUE;
        if( member(products_for_installation, product_parent(current_product)) )
            child_in_control = FALSE;
        /******************************************************************/

        /*************************
        Set Product Name variables
        **************************/
        COMPONENT_PRODUCT = w32grun60;                    /*Component product - Graphics Runtime*/
        required_products_list = list();
        required_products_to_install = list();
        dependency_list = list();
        verify_dependency_list = list();
        install_dependency_list = list();
        /*****************************/
        /*************************/

        /**************************
        Determine installation path
        ***************************/
        install_variable = "GRAPHICS60";
        default_home     = "%oracle_home%%dir_separator%GRAPH60";
        GRAPHICS60         = execute("%installer_home%%dir_separator%instloc.usr");
        /**************************/


        /*************************************************
         Get DOC60 variable location for HELP files install
         **************************************************/
         {
            DOC60 = translate(DOC60, ora_config);
         }
         [
           'UNBOUND_VARIABLE, 'UNBOUND_ENVIRONMENT_VARIABLE, 'FILE_NOT_FOUND:
            {
                  DOC60 = "%ORACLE_HOME%%dir_separator%TOOLS%dir_separator%DOC60";
                  if (not(exists(DOC60)))
                     make_directory(DOC60);
             }
         ]

         /************************************************/

        /********************************************************************
        Initialize total size of files
        *********************************************************************/
        total_sum = 0;

        /**********************************************
         Check if Graphics Runtime needs to be installed
         (no need to verify the PARENT because Runtime
         will be doing that anyway)
         ***********************************************/
         if(child_in_control)
         {
            EXECUTE_SCRIPT = "CHECK_COMPONENT_PRODUCT";
            execute("%installer_home%%dir_separator%d2kr2vrf.usr");

            if(install_component)
                total_sum = total_sum  + verify(COMPONENT_PRODUCT);
         }

        /******************
        Verify Dependencies
        *******************/
        EXECUTE_SCRIPT = "VERIFY_DEPENDENCIES";
        total_sum = total_sum + execute("%installer_home%%dir_separator%d2kr2vrf.usr");
        /******************/

         /*************************************************
        Determine which of the required products specified
        in required_products_list need to be installed
        **************************************************/
        while(not(empty(required_products_list)))
        {
            REQUIRED_PRODUCT = first(required_products_list);
            required_products_list = rest(required_products_list);

            EXECUTE_SCRIPT     = "CHECK_REQUIRED_PRODUCT";
            install_required_product = execute("%product_home%%dir_separator%d2kr2vrf.usr");

            if (install_required_product)
            {
                total_sum = total_sum + verify(REQUIRED_PRODUCT);
                add(required_products_to_install, REQUIRED_PRODUCT);
            }
        }
        /*************************************************/

        /*************************************************/

        if(child_in_control)
        {
           if(not(member(products_for_installation, w32graphl60)))
           {
                    total_sum = total_sum + verify(w32graphl60);
                    add(products_for_installation, w32graphl60);

            }
         }
        /**********************************************/

        total_sum = total_sum + sum(deinst, exe, res, ue, sql);

        return(total_sum);
        /***************************************************************************/
    }
    else
    {
        refresh_map_file = FALSE;
        return(0);
    }
}