/*Copyright (c) Oracle Corporation 1994.  All Rights Reserved */

/*****************************************************************************
  NAME
    fsql60.vrf - V3 analysis/product configuration script for Windows Forms
                 to create Database tables program items in the Oracle Forms/Reports
                 Administration program group

  DESCRIPTION
    This script checks dependencies and environment settings for the
    installation of the Windows Forms 6.0 Database Tables package.

  MODIFIED  MM-DD-YY  Reason
*****************************************************************************/

{
    SHARED_ORACLE_COMPLIANT = TRUE;

    {doit = execute("%installer_home%%dir_separator%%operating_system%.vrf");}
    [
        'UNBOUND_VARIABLE:
        {
            required_version = product_version(instver_product);
            temp = explode(required_version,".");
            required_version = implode(list(first(temp),first(rest(temp)),
                                            first(rest(rest(temp))),
                                            first(rest(rest(rest(temp))))),".");
            signal('FAILURE,instantiate(nls("instver_too_early1","The version of the Installer currently running is %%installer_version%%. The installation you have chosen requires version %%required_version%% or later. Please run version  %%required_version%% or later in order to perform this installation.")));
        }
    ]                                                                                /* This FAILURE will cause 3.0.x.x installer to exit gracefully. */

    /******************************************************************************************************
    START MAIN LOGIC
    ******************************************************************************************************/
    if(doit)
    {
        /****************************************************************
        Display the generic "Welcome to Oracle Developer"
        billboard if not already displayed, and if Developer release
        *****************************************************************/
        if(exists("%installer_home%%dir_separator%d2bb_01.bmp"))
        {
            if(DEVELOPER2000_RELEASE)
            {
                if(not(DEV2K_BB01))
                {
                    DEV2K_BB01 = TRUE;
                    ui_graphics("%installer_home%%dir_separator%d2bb_01.bmp");
                }
            }
        }
        /****************************************************************/


        /*****************************
        Set the VRF-INS script ratchet
        ******************************/
        vrf_ratchet = "6.0.8.13.0";

         main_product_version = "6.0.8.8.0";
         /***************************
         Check Installed Version
         ***************************/
         if(registered(product_name(current_product)))
         {
              check_installed_version = registry_version(registration(product_name(current_product)));
              if(earlier_version(check_installed_version, main_product_version))
              {
                   information_dialog(instantiate(product_upgrade_required),
                                      instantiate(product_upgrade_contents),
                                      instantiate(product_upgrade_help));
                   refresh_map_file = FALSE;
                   doit = FALSE;
                   return(0);
              }
          }
          else
          {
                information_dialog(instantiate(main_product_required),
                                   instantiate(main_product_contents),
                                   instantiate(main_product_help));
                 refresh_map_file = FALSE;
                 doit = FALSE;
                 signal('FAILURE, instantiate(halt_installation));
          }

        /*************** 04/21/95 ***********************
        Create a label with the product name, and version
        *************************************************/
        EXECUTE_SCRIPT = "CREATE_LABEL";
        execute("%product_home%%dir_separator%d2kr2vrf.usr");
        /********** End - 04/21/95 **********************/

        /******************************************************************
        child_in_control = TRUE ==> component product called explicitly
        child_in_control = FALSE ==> component product called by the PARENT
        *******************************************************************/
        child_in_control = TRUE;
        if( member(products_for_installation, product_parent(current_product) ))
            child_in_control = FALSE;
        /**********************************************************************/

        /*********************************
        Set product's parent name variable
        (required for the floppies)
        **********************************/
        PARENT_PRODUCT = w32forms60;
        COMPONENT_PRODUCTS_list = list(w32cdesql60);                /*Component product - Reports Runtime */
        COMPONENT_products_to_install = list();
        /***********************
        Create Dependencies List
        ************************/
        dependency_list = list(w32cdesql60);    
        verify_dependency_list = list(w32cdesql60);  
        install_dependency_list = list(w32cdesql60);

        /**************************
        Set installation path
        ***************************/
        default_home     = "%oracle_home%%dir_separator%TOOLS%dir_separator%DBTAB60%dir_separator%FORMS60";
        install_variable = "FORMS60";
	 /* FORMS60 = execute("%product_home%%dir_separator%instloc.usr");*/

        /***************************** End - 05/17/95 ****************************/

        /***************************************************************************
        Initialize total size of files
        ****************************************************************************/
        total_sum = 0;

        /*********************************
        Verify PARENT if explicitly called
        **********************************/
        install_parent = FALSE;
        if(child_in_control)
        {
            EXECUTE_SCRIPT = "VERIFY_PARENT";
            install_parent = execute("%product_home%%dir_separator%d2kr2vrf.usr");
        }

        if(install_parent)
            total_sum = total_sum + verify(product_parent(current_product));    /* verify Parent */


        while(not(empty(component_products_list)))
        {
            component_product = first(component_products_list);
            component_products_list = rest(component_products_list);
               if(child_in_control)
               {
                   EXECUTE_SCRIPT = "CHECK_COMPONENT_PRODUCT";
                   execute("%product_home%%dir_separator%d2kr2vrf.usr");

                   if(install_component)
                   {
                       add(component_products_to_install, COMPONENT_PRODUCT);
                       total_sum = total_sum  + verify(COMPONENT_PRODUCT);
                   }
                }
        }

        /*********************************
        Return total size of files
        *********************************/

        return(sum(deinst, sql, nocopy) + total_sum);    /* Added nocopy group here, as in Patch-3 the map file didn't
										have any file. So the version number was not getting updated
										So adding this group fools the installer into thinking that
										there are some files to be copied*/
        /***************************************************************************/
    }
    else
    {
        refresh_map_file = FALSE;
        return(0);
    }
}