/* Copyright (c) Oracle Corporation 1994.  All Rights Reserved */

/*****************************************************************************
  NAME
    rmts60.dei - V3 deinstallation script for Oracle Reports Server

  DESCRIPTION
    This script removes Windows Oracle Reports Server

  MODIFIED      MM/DD/YY    Reason
   pgupta    11/07/97   created.
*****************************************************************************/

{
    /************************************************
    Set necessary variables for deinstallation
    *************************************************/
    EXECUTE_SCRIPT = "SET_DEINSTALL_VARIABLES";
    execute("%installer_home%\d2kr2dei.usr");
    /************************************************/

    {doit = execute("%installer_home%%dir_separator%%operating_system%.dei");}
    [
        'UNBOUND_VARIABLE: signal('failure,instantiate(nls("instver_too_early2",
                                                           "The version of the Installer currently running is %%installer_version%%. The product(s) you have chosen to deinstall were installed with a later version of the Installer. Please use a later version of the Installer to deinstall these Product(s).")));
    ]

    if (doit)
    {
        /************************************************
        Create a label with the product name, and version
        *************************************************/
        EXECUTE_SCRIPT = "CREATE_LABEL";
        execute("%installer_home%%dir_separator%d2kr2dei.usr");
        /************************************************/

        /****************************
        Set up product name variables
        *****************************/
        PARENT_PRODUCT           = registry_parent(current_registry);
        PARENT_REGISTRY_NAME     = registry_name(PARENT_PRODUCT);
        COMPONENT_PRODUCT_STRING = "w32rrun60,w32rmts60";                    /*Component product - Reports Runtime*/
        /****************************/

        /***************************
        Validate deinstallation path
        ****************************/
        deinstall_variable = "RW60";
        section_heading    = registry_filename(PARENT_PRODUCT);
        EXECUTE_SCRIPT        = "GET_DEINSTALLATION_PATH";
        RW60           = execute("%installer_home%%dir_separator%d2kr2dei.usr");
        doc60 = translate("doc60","$oracle");
        /***************************/

        permit_retry_operations  = TRUE;
        permit_ignore_operations = TRUE;
        permit_process_operations= TRUE;
	
        /************************************************
	Remove Reports Server Service and Deinstall repname.cfg file if exists
        ************************************************/
	if(exists("%INSTALLER_HOME%\repname.cfg"))
	{
	   reports__server_name = translate("reports_server_name", "%INSTALLER_HOME%\repname.cfg");
           temp_var=current_directory();
           change_directory("%ORACLE_HOME%\bin");
           {spawnerror = spawn("rwmts60 -uninstall %reports__server_name% batch=yes");}
	   [ 'INVALID_FILE_NAME, 'OS_ERROR: continue(); ]
           change_directory("%temp_var%");
/*	   remove_file("%INSTALLER_HOME%\repname.cfg"); */
	}

        permit_retry_operations  = TRUE;
        permit_ignore_operations = TRUE;
        permit_process_operations= TRUE;

        /******************************************/

        /* Unregister Reports OCX */
        if (exists("%ORACLE_HOME%\bin\r25sxa32.ocx"))
        {
            {win32_asynchronous_spawn("%ORACLE_HOME%\bin\regsvr32 /u /s r25sxa32.ocx");}
            ['INVALID_FILE_NAME, 'FILE_NOT_FOUND, 'MEMORY_ERROR: continue();]
        }
         /***************************/

        /********************************
        Unreference Designer Dependencies
        *********************************/
        ui_product(instantiate(display_registry_label));
        ui_action(instantiate(unreference_dependencies));

        {unreference(registration(COMPONENT_PRODUCT_STRING), current_registry);}     /* Unreference Runtime */
        ['UNREGISTERED_PRODUCT: continue();]

        {unreference(registration(PARENT_REGISTRY_NAME), current_registry);}    /* Unreference Parent */
        ['UNREGISTERED_PRODUCT: continue();]
        /********************************/

        /*********************
        Unregister the product
        **********************/
        ui_product(instantiate(display_registry_label));
        ui_action(instantiate(deinstall_unregister));
        unregister(current_registry);
        /*********************/

        /************************************************
        Deinstall parent if no other child product exists
        *************************************************/
        EXECUTE_SCRIPT = "DEINSTALL_PARENT";
        execute("%installer_home%%dir_separator%d2kr2dei.usr");
        /************************************************/

        /********************
        Deinstall the product
        *********************/
        ui_product(instantiate(display_registry_label));

        ui_action(instantiate(deinstall_dll));
        remove(dll);
        remove(user);

        ui_action(instantiate(deinstall_exe));
        remove(exe);

        ui_action(instantiate(deinstall_files));
        remove(deinst);
	  remove(java);

        /********************/

        permit_retry_operations = FALSE;
    }
}