/* Copyright (c) Oracle Corporation 1996.  All Rights Reserved */

/*****************************************************************************
  NAME
    report60.vrf - V3 analysis/product configuration script for the
                   Oracle Reports 6.0 package

  DESCRIPTION
    This script checks dependencies and environment settings for the
    installation of the Oracle Reports 6.0 package

  MODIFIED    MM/DD/YY   Reason
   pgupta    11/07/97   created.
******************************************************************************/

{
    SHARED_ORACLE_COMPLIANT = TRUE;

    {doit = execute("%installer_home%%dir_separator%%operating_system%.vrf");}
    [
        'UNBOUND_VARIABLE:
        {
            required_version = product_version(instver_product);
            temp = explode(required_version, ".");
            required_version = implode(list(first(temp),first(rest(temp)),
                                            first(rest(rest(temp))),
                                            first(rest(rest(rest(temp))))), ".");
            signal('FAILURE, instantiate(nls("instver_too_early1",
                                             "The version of the Installer currently running is %%installer_version%%. The installation you have chosen requires version %%required_version%% or later. Please run version %%required_version%% or later in order to perform this installation.")));
        }
    ]                                                                       /* This FAILURE will cause 3.0.x.x installer to exit gracefully. */

    /*********************
    START MAIN LOGIC
    **********************/
    if (doit)
    {
        /****************************************************************
        Display the generic "Welcome to Oracle Developer"
        billboard if not already displayed, and if Developer release
        *****************************************************************/
        if(exists("%installer_home%%dir_separator%d2bb_01.bmp"))
        {
            if(DEVELOPER2000_RELEASE)
            {
                if(not(DEV2K_BB01))
                {
                    DEV2K_BB01 = TRUE;
                    ui_graphics("%installer_home%%dir_separator%d2bb_01.bmp");
                }
            }
        }
        /****************************************************************/

        /*****************************
        Set the VRF-INS script ratchet
        ******************************/
        vrf_ratchet = "6.0.0.0.1";

        /************************************************
        Create a label with the product name, and version
        *************************************************/
        EXECUTE_SCRIPT = "CREATE_LABEL";
        execute("%product_home%%dir_separator%d2kr2vrf.usr");
        /************************************************/

        /*************************
            Set Product Name variables
        **************************/
        {DESIGNER_PRODUCT = w32rdes60;}
        ['UNBOUND_VARIABLE: continue();]
        {RUNTIME_PRODUCT  = w32rrun60;}
        ['UNBOUND_VARIABLE: continue();]

        {REPORTS_RUNTIME = rwrun60.exe;}
        ['UNBOUND_VARIABLE: continue();]
        {REPORTS_BUILDER = rwbld60.exe;}
        ['UNBOUND_VARIABLE: continue();]

        /*************************/

        /***********************
        Create Dependencies List
        ************************/
        dependency_list     = list(w32tutil60, w32ssf60, w32repl60);    /*for referencing*/
        verify_dependency_list     = list(w32tutil60, w32gui60, w32ssf60, w32repl60);  /*to verify for installation*/
        install_dependency_list = list(w32repl60);
        /***********************/

        /**********************************************************************
        parent_in_control = TRUE ==> the complete product needs to be installed
        parent_in_control = FALSE ==> PARENT called by one of the components
        ***********************************************************************/
        parent_in_control = TRUE;
        if(not(member(selected_products, current_product)))
        {
            child_products = all_child_products(current_product);
            while(not(empty(child_products)))
            {
                next_child = first(child_products);
                child_products = rest(child_products);
                if(member(products_for_installation, next_child))
                    parent_in_control = FALSE;   
            }
        }
        /**********************************************************************/

        /**************************
        Determine installation path
        ***************************/
        install_variable = "RW60";
        default_home     = "%oracle_home%%dir_separator%REPORT60";
        section_heading  = product_filename(current_product);
        RW60             = execute("%product_home%%dir_separator%instloc.usr");
        /**************************/

        /**************************************************
         Calculate total size of files in this installation
        ***************************************************/
        total_sum = 0;

        /***********************************************
        If PARENT is explicitly called for installation,
        verify all the component products
        ************************************************/
        if(parent_in_control)
        {
            EXECUTE_SCRIPT = "VERIFY_COMPONENTS";
            total_sum = execute("%product_home%%dir_separator%d2kr2vrf.usr");
        }
        else
        {
            child_products = all_child_products(current_product);
            selected_components_list = list();
            size_component = 0;

            while(not(empty(child_products)))
            {
                next_child = first(child_products);
                if(member(selected_products, next_child))
                {
                    if(not(member(products_for_installation, next_child)))
                    {
                        size_component = verify(next_child);
                        if(size_component != 0)
                        {
                            add(selected_components_list, next_child);
                            total_sum = total_sum + size_component;
                        }
                    }
                }
                child_products = rest(child_products);
            }
        }
        /***********************************************/

        /******************
        Verify Dependencies
        *******************/
        EXECUTE_SCRIPT = "VERIFY_DEPENDENCIES";
        total_sum = total_sum + execute("%product_home%%dir_separator%d2kr2vrf.usr");
        /******************/

        total_sum = total_sum + sum(deinst);

        return(total_sum);
        /*******************/
    }
    else
    {
        refresh_map_file = FALSE;
        return(0);
    }
}