/* Copyright (c) Oracle Corporation 1996.  All Rights Reserved */

/****************************************************************************
  NAME
    report60.ins - V3 installation script for Oracle Reports 6.0 package

  DESCRIPTION
    This script installs Windows Oracle Reports 6.0 package.

  MODIFIED  MM/DD/YY    Reason
   pgupta    11/07/97   created.
*****************************************************************************/

{
    if (doit)
    {
        /*****************************
        Set the VRF-INS script ratchet
        ******************************/
        ins_ratchet = "6.0.0.0.1";

        execute("%installer_home%%dir_separator%%operating_system%.ins");

        permit_retry_operations  = TRUE;
        permit_ignore_operations = TRUE;
        permit_process_operations= TRUE;

        /******************
        Install the product
        *******************/
        ui_product(instantiate(display_product_label));

        ui_action(instantiate(install_files));
        copy(deinst);
        /******************/

        permit_retry_operations = FALSE;

        /***************************************
        Install all the components of the PARENT
        ****************************************/
        EXECUTE_SCRIPT = "INSTALL_COMPONENTS";
        execute("%installer_home%%dir_separator%d2kr2ins.usr");
        /***************************************/

        /*******************
         Install dependencies
        ********************/
        EXECUTE_SCRIPT = "INSTALL_DEPENDENCIES";
        execute("%installer_home%%dir_separator%d2kr2ins.usr");
        /*******************/

        permit_retry_operations = TRUE;

        /*********************************
        Register and Reference the product
        and remove delold.
        **********************************/
        EXECUTE_SCRIPT = "REGISTER_REFERENCE_PRODUCT";
        execute("%installer_home%%dir_separator%d2kr2ins.usr");

        /********************************************************************
        Reference all the components of the PARENT
        *********************************************************************/
        child_products_to_reference = all_child_products(current_product);
        EXECUTE_SCRIPT = "REFERENCE_COMPONENTS";
        execute("%installer_home%%dir_separator%d2kr2ins.usr");
        /********************************************************************/

        /*********************
        Reference dependencies
        **********************/
        ui_action(instantiate(reference_dependencies));

        while(not(empty(dependency_list)))
        {
            {reference(first(dependency_list), current_product);}
            ['UNREGISTERED_PRODUCT: continue();]

            dependency_list = rest(dependency_list);
        }
        /*********************/

        permit_retry_operations = FALSE;

        /************************************
        Set Environment Variables in registry
        *************************************/
        if(modify_oracle_ini)
        {
            modify(install_variable, RW60, ora_config, product_filename(current_product));
	    modify("REPORTS_RUNTIME","rwrun60.exe", ora_config, 'SUBKEY);
            modify("REPORTS_BUILDER","rwbld60.exe", ora_config, 'SUBKEY);
            
            /* Added the registry entry REPORTS60_SPLASH=true (bug# 1187004) */
            modify("REPORTS60_SPLASH","TRUE", ora_config, 'SUBKEY);
           
            win32_register_key("$ORACLE","",install_variable,'REPLICATE);
        }
        /************************************/

        /* register Reports OCX */
        if (exists("%ORACLE_HOME%\bin\r30sxa32.ocx"))
        {
            {win32_asynchronous_spawn("%ORACLE_HOME%\bin\regsvr32 /s r30sxa32.ocx");}
            ['INVALID_FILE_NAME, 'FILE_NOT_FOUND, 'MEMORY_ERROR: continue();]
        }
    }
    [
         'UNREGISTERED_PRODUCT: continue();
         'CANCEL: signal('FAILURE, instantiate(halt_installation));
    ]
}