/* Copyright (c) Oracle Corporation 1996.  All Rights Reserved */

/*****************************************************************************
  NAME
    rdes60.ins - V3 installation script for Oracle Report 6.0 Builder

  DESCRIPTION
    This script installs Windows Oracle Report 6.0 Builder.
  Last Update:
   JMADHAVI	12/08/99   Modified for domestic & export versions

*****************************************************************************/

{
    if (doit)
    {
        /*****************************
        Set the VRF-INS script ratchet
        ******************************/
        ins_ratchet = "6.0.0.0.1";

        execute("%installer_home%%dir_separator%%operating_system%.ins");

        permit_retry_operations  = TRUE;
        permit_ignore_operations = TRUE;
        permit_process_operations= TRUE;

        /***********************************
         Install Reports Runtime, if required
        ************************************/

        while(not(empty(component_products_to_install)))
        {
            install(first(component_products_to_install));
            component_products_to_install = rest(component_products_to_install);
        }
        /***********************************/


        /******************
        Install the product
        *******************/
        ui_product(instantiate(display_product_label));

        ui_action(instantiate(install_files));
        copy(deinst);

        /************************************************************
        Delete the Old Program Group if present and Install the new
        Program Group
        *************************************************************/

        if(exists("%ORACLE_HOME%/bin/rwbld60.exe"))
        {
          D2KOR60_GROUP = D2K60_GROUP_OLD;
          windows_delete_icons(exe);
          D2KOR60_GROUP = D2KOR60_GROUP_NEW;
        }
        /************************************************************/

        copy(exe);

        /************************************************************
        Display the "WIZARD - DRIVEN DEVELOPMENT" billboard
        if not already displayed, and if Developer release
        *************************************************************/
        if(exists("%installer_home%%dir_separator%d2bb_08.bmp"))
        {
            if(not(DEV2K_BB08))
            {
                DEV2K_BB08 = TRUE;
                ui_graphics("%installer_home%%dir_separator%d2bb_08.bmp");
            }
        }
        /************************************************************/


        ui_action(instantiate(install_files));
        copy(demo);
        copy(ue);
        copy(sql);
        copy(oci);
	copy(jar);
        copy(res);

        /******************/

        permit_retry_operations = FALSE;

        /***********************************
        Install Reports Language Supplement
        ************************************/
        if(child_in_control)
        {
            install_rdes=TRUE;
            install(w32repl60);
        }
        /************************
        Install required products
        *************************/
        while(not(empty(required_products_to_install)))
        {
            install(first(required_products_to_install));
            required_products_to_install = rest(required_products_to_install);
        }
        /*******************/

        /*********************************
        Register and Reference the product
        and remove delold
        **********************************/
        EXECUTE_SCRIPT = "REGISTER_REFERENCE_PRODUCT";
        execute("%installer_home%%dir_separator%d2kr2ins.usr");
        /*********************************/

        /*************************************
        Set variable in Registry
        **************************************/
        modify(qb_install_variable, BROWSER60, ora_config, product_filename(current_product));
        win32_register_key("$ORACLE","",qb_install_variable,'REPLICATE);

/*        if ((release == "D2k") || (release == "D2ksrv"))
        {
           modify("REPORTS60_DEV2K","TRUE",ora_config);
           win32_register_key("$ORACLE","","REPORTS60_DEV2K",'REPLICATE);
        }
        else
        { This is commended out as part of name_change */

           modify("REPORTS60_DEV2K","FALSE",ora_config);
           win32_register_key("$ORACLE","","REPORTS60_DEV2K",'REPLICATE);

/*        }     This is commended out as part of name_change */


        {
            if(modify_reports60_jni_lib)
            {
                modify("REPORTS60_JNI_LIB", reports60_jni_lib_var, ora_config, product_filename(product_parent(current_product)));
                win32_register_key("$ORACLE","","REPORTS60_JNI_LIB",'REPLICATE);
            }
        }
        [ 'UNBOUND_ENVIRONMENT_VARIABLE, 'FILE_NOT_FOUND: continue(); ]

        {
            if(modify_reports60_classpath)
            {
                modify("REPORTS60_CLASSPATH", reports60_classpath_var, ora_config, product_filename(product_parent(current_product)));
                win32_register_key("$ORACLE","","REPORTS60_CLASSPATH",'REPLICATE);
            }
        }
        [ 'UNBOUND_ENVIRONMENT_VARIABLE, 'FILE_NOT_FOUND: continue(); ]

        permit_retry_operations = TRUE;

        /***************************************************************
         Registering map variables except Installer_home and oracle_home
        ****************************************************************/
         win32_register_map_variable("RW60");
         win32_register_map_variable("DOC60");
         win32_register_map_variable("D2KOR60_GROUP");

        /*********************
        Reference Dependencies
        **********************/
        ui_action(instantiate(reference_dependencies));

        {reference(COMPONENT_PRODUCT, current_product);}
        ['UNREGISTERED_PRODUCT: continue();]

        {reference(w32ge60, current_product);}
        ['UNREGISTERED_PRODUCT: continue();]

        {reference(product_parent(w32ge60), current_product);}
        ['UNREGISTERED_PRODUCT: continue();]
        {reference(w32orqt60, current_product);}
        ['UNREGISTERED_PRODUCT: continue();]

        {reference(w32ordoc60, current_product);}
        ['UNREGISTERED_PRODUCT: continue();]

        {reference(current_product,product_parent(current_product));}
        ['UNREGISTERED_PRODUCT: continue();]


        {reference(product_parent(w32orqt60), current_product);}
        ['UNREGISTERED_PRODUCT: continue();]

        {reference(product_parent(w32ordoc60), current_product);}
        ['UNREGISTERED_PRODUCT: continue();]

        /*********************/

        permit_retry_operations = FALSE;
    }
    [
         'UNREGISTERED_PRODUCT: continue();
         'CANCEL: signal('FAILURE, instantiate(halt_installation));
    ]
}
