/* Copyright (c) Oracle Corporation 1996.  All Rights Reserved */
/*****************************************************************************
  NAME
    ca60.dei - V3 deinstall script for the Tools Utilities

  DESCRIPTION
    This script deinstalls the Tools Utilities

  MODIFIED    MM/DD/YY   Reason
*****************************************************************************/
{
     /************************************
     Set the directory separator according
     to the current operating system.
     *************************************/
     dir_separator = "\";
    /************************************/


    { doit = execute("%installer_home%%dir_separator%%operating_system%.dei"); }
    [
        'UNBOUND_VARIABLE: signal('failure,instantiate(nls("instver_too_early2",
                                                           "The version of the Installer currently running is %%installer_version%%. The product(s) you have chosen to deinstall were installed with a later version of the Installer. Please use a later version of the Installer to deinstall these Product(s).")));
    ]

    if (doit)
    {

        /************************
         Setup the nls() stuff for
         deinstall scripts
        *************************/
        EXECUTE_SCRIPT = "SET_DEINSTALL_VARIABLES";
        execute("%installer_home%%dir_separator%d2kr2dei.usr");
        /************************************************/

        /************************************************
        Create a label with the product name, and version
        *************************************************/
        EXECUTE_SCRIPT = "CREATE_LABEL";
        execute("%installer_home%%dir_separator%d2kr2dei.usr");
        /************************************************/

        /************************************************
        Create a label with the product name, and version
        *************************************************/
        installed_version = registry_version(current_registry);
        version_list      = explode(installed_version,".");
        msb_version_list  = list(first(version_list),
                             first(rest(version_list)));
        display_version   = implode(msb_version_list,".");

        display_registry_label = "%registry_label% %display_version%";

                ui_product(instantiate(display_registry_label));
        /************************************************/

        /*********************************************************
        For some reason, if any of the variables written to
        REGISTRY at the time of installation is not there, set the
        variables to the default value
        **********************************************************/

        {
            CA_UPREFS = v7_translate("CA_UPREFS");
            if (not(exists(CA_UPREFS)))
                signal('UNBOUND_ENVIRONMENT_VARIABLE);
        }
        [
            'OS_ERROR,'INVALID_FILE_NAME,
                'PERMISSION_DENIED,'UNBOUND_ENVIRONMENT_VARIABLE:
                CA_UPREFS = "%ORACLE_HOME%";
        ]

        {
            CA_GPREFS = v7_translate("CA_GPREFS");
            if (not(exists(CA_GPREFS)))
                signal('UNBOUND_ENVIRONMENT_VARIABLE);
        }
        [
            'OS_ERROR,'INVALID_FILE_NAME,
                'PERMISSION_DENIED,'UNBOUND_ENVIRONMENT_VARIABLE:
                CA_GPREFS = "%ORACLE_HOME%";
        ]
        /************************************************************/
        permit_retry_operations = TRUE;

        /*********************
        Unregister the product
        **********************/
        ui_product(instantiate(display_registry_label));
        ui_action(instantiate(deinstall_unregister));
        unregister(current_registry);
        /*********************/

        /*********************************************************************
        Deinstall the product
        **********************************************************************/
        ui_action(instantiate(deinstall_dll));
        remove(dll);

        ui_action(instantiate(deinstall_files));
        remove(grppref);
        remove(usrpref);

        ui_action(instantiate(deinstall_files));
        remove(deinstl);

        /*********************************************************************/

        permit_retry_operations = FALSE;

        /*****************************************
        Modify environment variables from Registry
        ******************************************/
        list_of_prefs_variables = list("CA_UPREFS", "CA_GPREFS");

        ui_action(instantiate(modify_variables));

        /****************************************************************
        Remove prefs variables (CA_UPREFS, and CA_GPREFS) from Registry
        *****************************************************************/
        while(not(empty(list_of_prefs_variables)))
        {
            next_variable = first(list_of_prefs_variables);

               {modify(next_variable, "", ora_config, "TUTIL60");}
               [ 'UNBOUND_ENVIRONMENT_VARIABLE, 'FILE_NOT_FOUND: continue(); ]

               list_of_prefs_variables = rest(list_of_prefs_variables);
        }
        /*****************************************/

        permit_retry_operations = FALSE;
    }
}