/* Copyright (c) Oracle Corporation 1997.  All Rights Reserved */
/*****************************************************************************
  NAME
    ott80.vrf - nt V3 installation verification script for ott 8.0.4.0.0 for NT.

  DESCRIPTION
    This script checks dependencies and environment settings for installation
    of OTT 8.0.4.0.0.

  OWNER
    Kiminari Akiyama

  MODIFIED    MM/DD/YY  Reason

  kpotter     3/98       version update for 805 EE
    kakiyama  05/13/97  Added Intype File Assistant
    kakiyama  04/12/97  Created.
*****************************************************************************/
{

  /* OSM Compliance */

  {
  /* OS variables */
   if (platform() == "nt")
   {
         prefix = "nt";
         instver_name = "ntinstver";
         install_name = "ntinstall";
   }
   else
   {
         prefix = "w95";
         instver_name = "w95instver";
         install_name = "w95install";
   }

   instver_prod = evaluate("instver_name");
   install_prod = evaluate("install_name");

   doit = execute("%installer_home%\%operating_system%.vrf");
  } [
    'UNBOUND_VARIABLE:
      {
        required_version = product_version(instver_prod);
        temp = explode(required_version,".");
        required_version = implode(list(first(temp),first(rest(temp)),
                                        first(rest(rest(temp))),
                                        first(rest(rest(rest(temp))))),".");
        signal('failure,instantiate(nls("instver_too_early1","The version of
the Installer currently running is %%installer_version%%. The installation you
have chosen requires version %%required_version%% or later. Please run version
%%required_version%% or later in order to perform this installation.")));
      }
    ]

/* end OSM */

 if (doit)
 {

/*****************************************************************************
   Set up strings for NLS ...
*****************************************************************************/

  installing_script_res  = nls("installing_script_res", "Installing %%product_label%% NLS Installer Resource Files...");

  ott_analyze_comment = nls("ott_analyze_comment","Analyzing %%product_label%% Dependencies...");
  ott_install_scripts = nls("ott_install_scripts","Installing %%product_label%% Installation Scripts...");
  ott_register_label  = nls("ott_register_label","Registering %%product_label%%...");
  ott_install_exec    = nls("ott_install_executables","Installing %%product_label%% Executables...");
  ott_install_config  = nls("ott_install_config","Installing %%product_label%% Configuration Files...");
  ott_install_msg     = nls("ott_install_msg","Installing %%product_label%% Message Files...");
  ott_install_samples = nls("ott_install_samples","Installing %%product_label%% Sample Files...");
  ott_install_ifa     = nls("removing_ifa","Installing Intype File Assistant Files...");
  ott_install_help    = nls("removing_help","Installing Intype File Assistant Help Files...");
  ott_install_env_var = nls("ott_install_env_var","Modifying %%product_label%% Environment Variables...");
  ott_expl            = nls("ott_expl", "%%product_label%% (ott80.exe) is currently running on this machine.  Please close all Oracle applications before installing %%product_label%%.

Silent mode installation of %%product_label%% terminated.");
  ott_run = instantiate(nls("ott_run", "%%product_label%% (ott80.exe) is currently running on this machine.  Please close all Oracle applications before installing %%product_label%%.

Choose OK after you have closed all Oracle applications and want to resume the installation of %%product_label%%.

Choose CANCEL to terminate the installation of %%product_label%%.
      "));
  ott_inst_term = instantiate(nls("ott_inst_term", "%%product_label%% installation terminated."));
  ott_run_content = nls("ott_run_content", "%product_label%");
  ott_run_help = instantiate(nls("ott_run_help", "The Oracle Installer has detected that %%product_label%% (ott80.exe) is currently running on this machine.  Please close all Oracle applications before installing this %%product_label%%.

Choose OK after you have closed all Oracle applications and want to resume the installation of %%product_label%%.

Choose CANCEL to terminate the installation of %%product_label%%.

"));


/*****************************************************************************
   Start main logic ...
*****************************************************************************/

  ui_product(product_label);
  ui_action(instantiate(ott_analyze_comment));

  vrf_ratchet = "8.0.5.0.0";

  ifa = "%oracle_home%\JRE11\classes\ifa";

  done = FALSE;
  while(not(done))
  { if (operating_system == "win95")
    {
      move_file("%ORACLE_HOME%\bin\ott80.exe", "%ORACLE_HOME%\bin\ott80.exe");
      move_file("%ORACLE_HOME%\bin\ott.exe", "%ORACLE_HOME%\bin\ott.exe");
    }
    else if (operating_system == "nt")
    {
      copy_file("%ORACLE_HOME%\bin\ott80.exe", "%ORACLE_HOME%\tmp.exe");
      remove_file("%ORACLE_HOME%\bin\ott80.exe");
      move_file("%ORACLE_HOME%\tmp.exe", "%ORACLE_HOME%\bin\ott80.exe");

      copy_file("%ORACLE_HOME%\bin\ott.exe", "%ORACLE_HOME%\tmp.exe");
      remove_file("%ORACLE_HOME%\bin\ott.exe");
      move_file("%ORACLE_HOME%\tmp.exe", "%ORACLE_HOME%\bin\ott.exe");

    }
    done = TRUE;
  }
  [ 'PERMISSION_DENIED, 'INVALID_FILE_NAME, 'OS_ERROR, 'WRITE_ERROR:
    {
      if (silent_mode)
         signal('FAILURE, instantiate(ott_expl));
      else
         information_dialog(ott_run, ott_run_content, ott_run_help);
    }
  'FILE_NOT_FOUND:
       done = TRUE;
  ]

  {
    pro80 = translate("PRO80", ora_config, product_filename(current_product));
    if (not(exists(pro80)))
      signal('UNBOUND_ENVIRONMENT_VARIABLE);
  }
    [ 'OS_ERROR,'INVALID_FILE_NAME,'FILE_NOT_FOUND,
      'PERMISSION_DENIED,'UNBOUND_ENVIRONMENT_VARIABLE:
      {
        pro80 = "%oracle_home%\PRO80";
      }
    ]

  {
    ott80 = translate("OTT80", ora_config, product_filename(current_product));
    if (not(exists(ott80)))
      signal('UNBOUND_ENVIRONMENT_VARIABLE);
  }
    [ 'OS_ERROR,'INVALID_FILE_NAME,'FILE_NOT_FOUND,
      'PERMISSION_DENIED,'UNBOUND_ENVIRONMENT_VARIABLE:
      {
        ott80 = "%oracle_home%\OTT80";
      }
    ]

/*****************************************************************************
   Return the total size of files to be installed ...
*****************************************************************************/

    total_sum = verify(w32rsf80);
    return(total_sum + sum(deinstl, exec, config, msg, nls_abbreviation, msgpgo, nls_abbreviation, ifaw, stub, help) + verify(w32jre11) +verify(jsf803) + verify(jdbc));
  }
  else
  {
     refresh_map_file = FALSE;
     return(0);
  }
}