create or replace package body odwahelp
is

/*****************************************************************************************
Purpose         Provide access to the On-Line help system of ODWA6i

Usage

Remarks

Revision history
When        Who                                Construct
  Revision  What
------------------------------------------------------------------------------------------
$REVISION_HISTORY$
06-Dec-2002   Kannan Parthasarathy
              - B2695653 Fixed.
14-Nov-2002   Kannan Parthasarathy
              - Fixed OAC p1 violations.
06-oct-2002   Kannan Parthasarathy
              - Bug 2610181: Changed TITLE of the help page.
24-sep-2002   Kannan Parthasarathy
              - Changes made to accommodate new logo.
21-feb-2001   Lucas Jellema
  1.6         - issue 195 Also See.. is sorted in wrong order [odwa project/195%]
30-jan-2001   Lucas Jellema
  1.5         - show static documents
              - function help_url: do not return URL+gif if help item does not exist (ISSUE 151)
              - procedure help_bar_frame: only show create/edit button when odwa_pref edit_help_allowed =Y (ISSUE= 150)
              -
29-jan-2001   Lucas Jellema
  1.4         - remove odwa_help_tree
25-jan-2001   Lucas Jellema
  1.3         - use preference edit_help_allowed to determine whether the edit/create help item icons should be displayed

15-jan-2001   Peter Ebell
  1.2         - Added Self Service header
12-jan-2001   Lucas Jellema
  1.1         Add functionality to Edit and Create Help Items

22-dec-2000   Lucas Jellema
  1.0         Initial creation.
*****************************************************************************************/

--
-- private constants
--
REVISION_LABEL        constant varchar2(30) := '$x.y::1.6             $';
PACKAGE_NAME          constant varchar2(30) := 'ODWAHELP';

-- this variable holds the value of the (Virtual) Document directory, derived
-- from the doc_path odwa_preference
g_odwa_doc_path   varchar2(2000);
g_allow_help_edit boolean;

type t_htt_table
is table of varchar2(4000)
index by binary_integer
;

g_htt_table t_htt_table;

  cursor c_him ( b_him_id in number)
  is
  select him.id
  ,      him.document
  ,      him.description
  ,      him.keywords
  from   odwa_help_items him
  where  him.id = b_him_id
  ;


  cursor c_hnd
         ( b_hnd_id in number
         ) is
  select hnd.seq_in_parent
  ,      hnd.tree_level
  ,      hnd.display_label
  ,      hnd.him_id
  ,      hnd.parent_node
  ,      hnd.id
  from   odwa_help_nodes hnd
  where  hnd.id = b_hnd_id
  ;

 cursor c_hnd_for_him
         ( b_him_id in number
         ) is
  select hnd.seq_in_parent
  ,      hnd.tree_level
  ,      hnd.display_label
  ,      hnd.him_id
  ,      hnd.parent_node
  ,      hnd.id
  from   odwa_help_nodes hnd
  where  hnd.him_id = b_him_id
  ;

  r_hnd c_hnd%rowtype;

   cursor c_hnd_tree
          ( b_parent_node in number default 0
          )
   is
    select hnd.seq_in_parent
    ,      hnd.tree_level
    ,      hnd.display_label
    ,      hnd.him_id
    ,      hnd.parent_node
    ,      hnd.id
    ,      hnd.rowid hnd_rowid
    from   odwa_help_nodes hnd
    start
    with   hnd.parent_node = b_parent_node
    connect
    by     prior id = parent_node
    ;

  cursor c_hnd_chld
         ( b_parent_hnd_id in number
         ) is
  select hnd.seq_in_parent
  ,      hnd.tree_level
  ,      hnd.display_label
  ,      hnd.him_id
  ,      hnd.parent_node
  ,      hnd.rowid hnd_rowid
  ,      hnd.id
  from   odwa_help_nodes hnd
  where  hnd.parent_node = b_parent_hnd_id
  order
  by     hnd.seq_in_parent
  ;

  r_him c_him%rowtype;

-- this procedure will fetch the row from ODWA_HELP_ITEMS for the indicated
-- help item and store it in r_him
procedure cache_him
( p_him_id in number
) is
begin
  open c_him( b_him_id => p_him_id);
  fetch c_him
  into  r_him;
  close c_him;
end; -- cache_him

-- this procedure will fetch the row from ODWA_HELP_NODES for the indicated
-- help node and store it in r_hnd
procedure cache_hnd
( p_hnd_id in number
) is
begin
  open c_hnd( b_hnd_id => p_hnd_id);
  fetch c_hnd
  into  r_hnd;
  close c_hnd;
end; -- cache_him

-- this procedure will fetch the row from ODWA_HELP_NODES for the indicated
-- help node and store it in r_hnd
procedure cache_hnd_for_him
( p_him_id in number
) is
begin
  open c_hnd_for_him( b_him_id => p_him_id);
  fetch c_hnd_for_him
  into  r_hnd;
  close c_hnd_for_him;
end; -- cache_him

-- this procedures retrieves and caches in g_htt_table
-- the help text blocks for help item b_him_id
procedure cache_htt
( p_him_id in number
) is
  cursor c_htt( b_him_id in number)
  is
    select htt.txt
    from   odwa_help_text htt
    where  htt.him_id = b_him_id
    order
    by     htt.seq
    ;
begin
  open c_htt( b_him_id => p_him_id);
  FETCH c_htt
  BULK COLLECT
  INTO  g_htt_table;
  close c_htt;
end;


-- this procedure writes a JavaScript function into the HeadSection of an HTML document
-- the function, showHelp( id), can be called to bring up a window with help on a specific topic
-- calls to this function can be retrieved from the function odwahelp.help_url
procedure js_invoke_help
is
begin
  htp.p(' <SCRIPT LANGUAGE="JavaScript"><!--

  function showHelp(id)
  {
    window2=open
            ( ''odwahelp.show_help_item?p_session_id='||to_char(odwactxt.get_session_id)
                        ||chr(38)||'p_him_id=''+id'
            ||', ''helpWindow''
            , ''toolbar=no,scrollbars=yes,location=no,directories=no''
             +'',status=no,menubar=no,resizable=yes''
            );
    window2.moveTo(360,30);
    window2.innerHeight=520;
    window2.innerWidth=600;
    window2.focus();
  }
    //--></SCRIPT>
    <NOSCRIPT>'|| ROB_msg.Getmsg(Rob_Msg.ACC005_NOSCRIPT,'','','','')||
    '</NOSCRIPT>'
  );
end; -- js_invoke_help

-- this function returns the JavaScript call to be made to invoke the help for the indicated item
function help_call
( p_him_id        in number
) return varchar2
is
begin
  return 'showHelp('''||to_char(p_him_id)||''')';
end; --help_url



-- this function will return a url to show the help for the indicated item
-- note that this url should only be used in a document that contains the showHelp function
function help_url
( p_him_id        in number
, p_icon          in boolean default true
, p_text          in varchar2 default  null
, p_alt_text      in varchar2 default  null
, p_top           in boolean default false  -- is the JavaScript function to be located in the Top (Window) frame (instead of the current frame)
) return varchar2
is
begin
  -- $% x.y $ if help item does not exist, then return '' else return URL
  cache_him( p_him_id => p_him_id);
  if r_him.id is null
  then
    return '';
  else
    return '<A href="javascript:'
    ||cdwpbase.ifThenElse
      ( p_top
      , 'top.'
      )
    ||help_call( p_him_id)||'">'
          ||cdwpbase.ifThenElse
            ( p_icon
            , cdwp.add_images
              ( '{help.gif}'
              , p_attributes => cdwpbase.ifThenElse
                                ( p_alt_text is not null
                                , 'ALT="'||p_alt_text||'"'
                                )
              )
            )
          ||p_text
          ||'</A>'
          ;
  end if; -- r_him.id is null
end; --help_url


-- procedure display the result of a Search in the helpItemFrame as initiated from the Search item
-- in the helpBarFrame
procedure searchHelp
( searchString in varchar2
, p_session_id in number
) is
  l_search_string varchar2(200):= lower(ltrim(rtrim(searchString)));
  cursor c_him
         ( b_searchString in varchar2)
  is
  select him.id
  ,      him.document
  ,      him.description
  ,      him.keywords
  from   odwa_help_items him
  where  instr(lower(him.description), b_searchString) > 0
  or     instr(lower(him.keywords), b_searchString) > 0
  order
  by     him.description
  ;

 -- this function may help perform a more refined/sophisticated search
  function inSearch
  ( p_description in varchar2
  , p_keywords    in varchar2
  ) return boolean
  is
  begin
    return true;
  end; --inSearch

begin
  -- create session when necessary, refresh session cache, set workarea context
  -- from here on reference to odwactxt.get_... functions for any context value
  odwactxt.update_context
  ( p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'helpBarFrame'
  , p_session_id    => p_session_id
  );
  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  cdwp.include_report_styles;
  htp.headClose;
  htp.bodyopen
  ( cattributes => 'BGCOLOR="#FFFFFF"'
  );
  cdwp.p
  ( Rob_msg.GetMsg(Rob_msg.DSP240_ODWAHELP_SRCHR,'','','','')
  ||searchString
  , p_style => 'partitle'
  );
  htp.nl;
  for r_him in c_him( b_searchString => l_search_String) loop
     if inSearch( r_him.description, r_him.keywords)
     then
      /* open new window */
       htp.p
       ( '<A href="javascript:parent.'||odwahelp.help_call(p_him_id => r_him.id)||'">'
       ||r_him.description
       ||'</A><BR>'
       );
     end if; -- inSearch
  end loop; -- r_him
  htp.bodyClose;
  htp.htmlClose;
end; -- searchHelp

-- this procedure will write a piece of HTML that displays a search item that, when pressed, will result
-- in a search being executed in the On Line Help for the search string
procedure writeSearchHelp
is
begin
  htp.p( '
 <TABLE BORDER=0 ALIGN=RIGHT CELLSPACING=0 CELLPADDING=0>
<FORM ACTION="odwahelp.searchHelp" TARGET="helpItemFrame">
        <TR><TD ALIGN=center VALIGN="BOTTOM">
<HR NOSHADE SIZE="1" WIDTH="100%">
<FONT FACE="ARIAL" SIZE=1 COLOR="#000099" STYLE="font-weight:bold">'
 || Rob_msg.Getmsg(Rob_msg.CAP314_ODWAHELP_SEARCH,'','','','')
 || '</FONT>
<INPUT TYPE=TEXT NAME="searchString" SIZE=9 MAXLENGTH=60><FONT SIZE=1 FACE="ARIAL">
<INPUT TYPE=HIDDEN NAME="p_session_id" VALUE="'||to_char(odwactxt.get_session_id)||'"><FONT SIZE=1 FACE="ARIAL">
                </TD></TR></FORM></TABLE>
   ');
end; -- writeSearchHelp

procedure helpBarFrame
( p_session_id    in   number default null
, p_him_id        in   number -- the help item id (refers to table ODWA_HELP_ITEMS.id)
, p_hnd_id               in   number default null -- the node id ODWA_HELP_NODES table
) is
  l_menu_bar varchar2(500);
begin
  -- create session when necessary, refresh session cache, set workarea context
  -- from here on reference to odwactxt.get_... functions for any context value
  odwactxt.update_context
  ( p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'helpBarFrame'
  , p_session_id    => p_session_id
  );
  if p_hnd_id is null
  then
    cache_hnd_for_him
    ( p_him_id => p_him_id
    );
  else
    cache_hnd( p_hnd_id);
  end if;
  cache_him( p_him_id);

  l_menu_bar:=cdwp.add_images( p_text => '{ft-left.gif}');
  l_menu_bar:= l_menu_bar
        ||htf.anchor2
            ( ctext=> cdwp.add_images
                        ( '{editprivsgr.gif}'
                        , p_attributes => 'ALT="Edit Help Item"'
                        )
            , curl => 'odwahelp.editHelpItem?'
                      ||'p_session_id='||to_char(p_session_id)
                      ||chr(38)||'p_him_id='||to_char(p_him_id)
                      ||chr(38)||'p_hnd_id='||to_char(r_hnd.id)
           , ctarget => 'helpFrame'
           )
        ||htf.anchor2
          ( ctext=> cdwp.add_images
                      ( '{additiongr.gif}'
                      , p_attributes => 'ALT="Create New Help Item"'
                      )
          , curl => 'odwahelp.editHelpItem?'
                    ||'p_session_id='||to_char(p_session_id)
          , ctarget => 'helpFrame'
         );
  l_menu_bar:= l_menu_bar
    ||cdwp.add_images
      ( p_text => '{ft-right.gif}'
      , p_attributes=> ' Qwidth="25" '
      )
    ;

  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  cdwp.include_report_styles;
  htp.headClose;
  htp.bodyopen
  ( cattributes => 'BGCOLOR="#FFFFFF"'
  );
  if g_allow_help_edit
  then
    htp.tableopen( cattributes => 'BORDER="0" align="RIGHT"');  -- 1.4  bgcolor="88DDF9"
    cdwp.tableRowOpen;
    htp.tabledata
    ( cvalue=> l_menu_bar
    , calign => 'right'
    , cattributes => 'Zwidth="400" ABGCOLOR="#cccccc"'
    );
    cdwp.tableRowClose;
    cdwp.tableClose;
  end if; --   g_allow_help_edit = true
  writeSearchHelp;
  cdwp.p
  ( nvl( nvl( r_him.description, r_hnd.display_label) , Rob_msg.GetMsg(Rob_msg.DSP241_ODWAHELP_TITLE,'','','',''))
  , p_style => 'partitle'
  );
  htp.bodyClose;
  htp.htmlClose;
end; -- helpBarFrame

-- this procedure will write a framework HTML document
-- fleshed out with the text stored for the current Help Item p_him_id
-- in the table ODWA_HELP_TET.

procedure helpItemFrame
( p_session_id    in   number default null
, p_him_id        in   number -- the help item id (refers to table ODWA_HELP_ITEMS.id)
, p_hnd_id               in   number default null -- the node id ODWA_HELP_NODES table
) is
  l_first boolean;
  l_recursive_check number(2):=1;
  cursor c_htt
         ( b_him_id in number
         ) is
    select htt.txt
    from   odwa_help_text htt
    where  htt.him_id = b_him_id
    order
    by     htt.seq
    ;

  procedure also_see_children
  ( p_level  in number
  , p_hnd_id in number
  ) is
    cursor c_hnd_chld
         ( b_parent_hnd_id in number
         ) is
  select hnd.seq_in_parent
  ,      hnd.tree_level
  ,      hnd.display_label
  ,      hnd.him_id
  ,      hnd.parent_node
  ,      hnd.rowid hnd_rowid
  ,      hnd.id
  from   odwa_help_nodes hnd
  where  hnd.parent_node = b_parent_hnd_id
  order
  by     hnd.seq_in_parent
  ;

  begin
     l_recursive_check:= l_recursive_check+1;
     for r_hnd_chld  in c_hnd_chld( b_parent_hnd_id => p_hnd_id) loop
       if l_first
       then
          l_first:= false;
          htp.p('<h3>'||Rob_msg.Getmsg(Rob_msg.CAP313_ODWAHELP_SEE,'','','','')||'</h3>');
        end if; -- l_first
        htp.p
        ( cdwpbase.nbsp( p_level * 5)
        ||'<A href="javascript:parent.document.location.href=''odwahelp.show_help_item?p_session_id='||to_char(odwactxt.get_session_id)
        ||chr(38)||'p_him_id='||to_char(r_hnd_chld.him_id)
        ||'''">'
        ||r_hnd_chld.display_label
        ||'</A>'
        ||'<BR>'
        );
        also_see_children
        ( p_level + 1
        , r_hnd_chld.id
        );
      end loop; -- r_hnd_chld
  end; -- also_see_children

begin
  -- create session when necessary, refresh session cache, set workarea context
  -- from here on reference to odwactxt.get_... functions for any context value
  odwactxt.update_context
  ( p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'helpItemFrame'
  );
  cache_him( p_him_id);
  if p_hnd_id is null
  then
    cache_hnd_for_him
    ( p_him_id => p_him_id
    );
  else
    cache_hnd( p_hnd_id);
  end if;
  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  cdwp.include_report_styles;
  htp.headClose;
  htp.bodyopen
  ( cattributes => 'BGCOLOR="#FFFFFF"'
  );
  for r_htt in c_htt( b_him_id => p_him_id) loop
    htp.p
     ( cdwp_txt.add_ent_anchors
       ( ''
       , r_htt.txt
       , ''
      )
     );
  end loop; -- r_htt
  l_first:= true;
  if p_him_id is not null
  then
    for r_hnd_for_him in c_hnd_for_him( b_him_id => p_him_id) loop
      -- now also show the sub-items according to the tree definition
      also_see_children
      ( p_level => 1
      , p_hnd_id => r_hnd_for_him.id
      );
    end loop; -- r_hnd_for_him
  else
    also_see_children
    ( p_level => 1
    , p_hnd_id => p_hnd_id
    );
  end if; -- p_him_id is not null
  htp.bodyClose;
  htp.htmlClose;
end; -- helpItemFrame


-- this procedure writes the JavaScript function that is necessary to be able to invoke
-- a viewlet from within the current document
-- IF this procedure is called between htp.headOpen and htp.headClose, Viewlets can be linked
-- to in the HTML page using the following URL:
-- href="javascript:parent.showViewlet('<viewletname>')"
procedure js_invoke_viewlet
is
begin
   htp.p('
   <script language="javaScript">
                   <!--
                   function isLeelouCompliant()
                   {
                        answer=false;
                        version=Math.round(parseFloat(navigator.appVersion) * 1000);
                        if (navigator.appName.substring(0,9) == "Microsoft")
                        {
                            if(version>=4000) answer=true;
                        }
                        if (navigator.appName.substring(0,8) == "Netscape")
                        {
                            if ((navigator.appVersion.indexOf("Win")> 0) & (version>=4060)) answer=true;
                            else
                            if ((navigator.appVersion.indexOf("Linux")> 0) & (version>=4060)) answer=true;
                            else
                            if ((navigator.appVersion.indexOf("SunOS")> 0) & (version>=4060)) answer=true;
                            else
                            if ((navigator.appVersion.indexOf("Mac")> 0) & (version>=5000)) answer=true;
                        }
                        // other one with plug-in (ie opera+plug_in)
                        plugins=navigator.plugins;
                        if (plugins!=null)
                        {
                            for(i=0;i!=plugins.length;i++)
                                 if((plugins[i].name.indexOf("Java Plug-in")>=0) & (plugins[i].name.indexOf("1.0")<0))
                                     answer=true;
                        }
                        return answer;
                   }

                   function openViewlet(htmlFile,htmlWidth,htmlHeight)
                   {
                        str = ''resizable=0,toolbar=0,menubar=0,'';
                        str = str + ''scrollbars=0,status=0,location=0,directory=0,width=350,height=200'';
                        if(!isLeelouCompliant())
                        {
                             open("http://www.qarbon.com/warning/index.html",''Leelou'',str);
                        }
                        else
                        {
                             if(document.all)
                             {
                                   htmlWidth+=5;
                                   htmlHeight+=10;
                             }

                        window.open(htmlFile,''Leelou'',''width=''+htmlWidth+'',height=''+htmlHeight+'',top=10,left=20'');
                        }
                   }

                   function showViewlet (viewletName)
                   {
                     openViewlet('''||g_odwa_doc_path||'''+ viewletName+ ''_viewlet.html'',859,680);
                   }
                   // -->
                   </script>
                    <NOSCRIPT>'|| ROB_msg.Getmsg(Rob_Msg.ACC005_NOSCRIPT,'','','','')||
                    '</NOSCRIPT>
   ');
end; -- js_invoke_viewlet

-- main procedure
-- -------------------------------
-- |       helpBarFrame            |
-- |                             |
-- |                             |
-- |-----------------------------|
-- |                             |
-- |       helpItemFrame           |
-- |                             |
-- -------------------------------
--
--
procedure show_help_item
( p_session_id    in   number default null
, p_him_id        in   number -- the help item id (refers to table ODWA_HELP_ITEMS.id)
, p_hnd_id        in   number default null -- the node id ODWA_HELP_NODES table
) is
  l_menu_bar varchar2(500);
begin
  -- create session when necessary, refresh session cache, set workarea context
  -- from here on reference to odwactxt.get_... functions for any context value
  odwactxt.update_context
  ( p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'show_help_item'
  );
  cache_him( p_him_id);
  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  cdwp.include_report_styles;
  htp.title
  ( Rob_msg.GetMsg(Rob_msg.DSP241_ODWAHELP_TITLE,'','','','')
  ||r_him.description
  );
  js_invoke_viewlet;
  js_invoke_help;
  htp.headClose;
  htp.framesetopen
  ( crows       =>  '15%,85%'
  , cattributes => 'BORDER="0" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'" LONGDESC=odwahelp.rightSide?p_session_id=&p_him_id=150'
  );
  htp.frame
  ( csrc => 'odwahelp.helpBarFrame?p_session_id='
          ||to_char(odwactxt.get_session_id)
          ||chr(38)||'p_him_id='||nvl(to_char(p_him_id), cdwpbase.ifThenElse( p_hnd_id is null, '1000'))
            ||chr(38)||'p_hnd_id='||to_char(p_hnd_id)
  , cname=> 'helpBarFrame '
  , cattributes=> 'LONGDESC="" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.ACC009_BROW_FRAME,'','','','')||'"'
  );
  -- if the help item refers to a static document, the helpItemFrame
  -- should be linked to that document
  -- if the help item is contained in the ODWA_HELP_TEXT table, the
  -- procedure helpItemFrame is invoked
  if r_him.document is null
  then
    htp.frame
    ( csrc => 'odwahelp.helpItemFrame?p_session_id='
            ||to_char(odwactxt.get_session_id)
          ||chr(38)||'p_him_id='||nvl(to_char(p_him_id), cdwpbase.ifThenElse( p_hnd_id is null, '1000'))
            ||chr(38)||'p_hnd_id='||to_char(p_hnd_id)
    , cname=> 'helpItemFrame'
    , cattributes=>'LONGDESC="" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'"'
    );
  else
    htp.frame
    ( csrc => g_odwa_doc_path||r_him.document  -- 1.5
    , cname=> 'helpItemFrame'
    , cattributes=>'LONGDESC="" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'"'
    );
  end if; -- r_him.document is null
  htp.framesetclose;
  htp.bodyopen
  ( cattributes => 'BGCOLOR="#FFFFFF"'
  );
  htp.bodyClose;
  htp.htmlClose;
end; -- show_help_item

-- initialize text areas
procedure js_init
is
begin
  htp.p
  (' <SCRIPT LANGUAGE="JavaScript"><!--
  function init()
  {
  ');
  for i in 1..g_htt_table.count loop
    htp.p(' document.himForm.txt'||to_char(i)||'.value="'
   ||replace(replace( replace( g_htt_table(i),chr(13),'\r'),chr(10),''),'"','\"')
   ||'";'
   );
  end loop;
  htp.p('

   } // init()
    //--></SCRIPT>
    <NOSCRIPT>'|| ROB_msg.Getmsg(Rob_Msg.ACC005_NOSCRIPT,'','','','')||
    '</NOSCRIPT>'
  );
end; -- js_init


procedure js_addHelpReference
is
begin
  htp.p
  (' <SCRIPT LANGUAGE="JavaScript"><!--
  function addHelpReference()
  {
    top.status ="How to add a help reference: <A href=javascript:parent.showHelp(<help item id>)>text</A>";
    alert("How to add a help reference: <A href=javascript:parent.showHelp(<help item id>)>text</A>");
   } //
  function addViewletReference()
  {
    top.status ="How to add a viewlet reference";
    alert("How to add a viewlet reference");
   } //
    //--></SCRIPT>' ||
    ' <NOSCRIPT>'|| ROB_msg.Getmsg(Rob_Msg.ACC005_NOSCRIPT,'','','','')||
    '</NOSCRIPT>'
    );
end; -- js_addHelpReference


-- this procedure displays an existing or new help item in editable form items
procedure editHelpItem
( p_session_id             in number
, p_him_id                 in number default null
, p_hnd_id               in   number default null -- the node id ODWA_HELP_NODES table
) is
  l_txt1 varchar2(4000);
  l_txt2 varchar2(4000);
  l_txt3 varchar2(4000);
begin
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'editHelpItem'
  );
  cache_him( p_him_id);
  cache_htt( p_him_id);
  cache_hnd( p_hnd_id);
  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  cdwp.include_report_styles;
  js_invoke_viewlet;
  js_invoke_help;
  js_init;
  js_addHelpReference;
  htp.headClose;
  htp.bodyopen
  ( cattributes => 'BGCOLOR="#FFFFFF" onLoad="init()"'
  );
  htp.formopen
  ( curl => 'odwahelp.saveHelpItem'
  , cmethod => 'POST'
  , cattributes => 'NAME="himForm"'
  );
  htp.formhidden(cname => 'p_session_id', cvalue => to_char(odwactxt.get_session_id));
  htp.formhidden(cname => 'him_id', cvalue => to_char(p_him_id));
  htp.formhidden(cname => 'p_hnd_id', cvalue => to_char(p_hnd_id));
  htp.p( '<INPUT TYPE=BUTTON onClick="himForm.submit()" VALUE="Submit" >');
  htp.p( '<INPUT TYPE=BUTTON onClick="self.document.location.href=''odwahelp.helpItemFrame?p_session_id='||to_char(odwactxt.get_session_id)
  ||chr(38)||'p_him_id='||to_char(p_him_id)||'''" VALUE="Cancel" >');
  htp.p( '<INPUT TYPE=BUTTON onClick="addHelpReference()" VALUE="Help Ref" >');

  htp.tableopen;

  cdwp.tablerowopen;
  cdwp.tabledataheading('#'||to_char(p_him_id));
  cdwp.tabledatavalue( htf.formtext(cname => 'p_description' ,csize => 40 ,cmaxlength => 200 ,cvalue => nvl( r_him.description, r_hnd.display_label)));
  cdwp.tablerowclose;
  cdwp.tablerowopen;
  cdwp.tabledataheading(p_heading => Rob_msg.GetMsg(Rob_msg.DSP242_ODWAHELP_STDOC,'','','',''));
  cdwp.tabledatavalue( htf.formtext(cname => 'p_document' ,csize => 30 ,cmaxlength => 200 ,cvalue => r_him.document));
  cdwp.tablerowclose;
  cdwp.tablerowopen;
  cdwp.tabledataheading(Rob_msg.GetMsg(Rob_msg.CAP120_ODWAHELP_KW,'','','',''));
  cdwp.tabledatavalue( htf.formtext(cname => 'p_keywords' ,csize => 50 ,cmaxlength => 500 ,cvalue => r_him.keywords));
  cdwp.tablerowclose;
  cdwp.tablerowopen;
  cdwp.tabledataheading(Rob_msg.GetMsg(Rob_msg.DSP243_ODWAHEMP_PNODE,'','','',''));
  htp.p('<TD ALIGN=LEFT>');
  htp.formselectopen
  ( cname   => 'p_parent_node'
  , cprompt => ''
  );
  htp.p
  ( '<OPTION VALUE=""'
   ||cdwpbase.ifThenElse
     ( r_hnd.id is null
     , 'SELECTED=Y'
     )
   ||'>'
   ||'Not in the helptree'
   );
  htp.p
  ( '<OPTION VALUE="0"'
   ||cdwpbase.ifThenElse
     ( r_hnd.tree_level= 1
     , 'SELECTED=Y'
     )
   ||'>'
   ||'Root Node'
   );
  for r_hndtree in c_hnd_tree loop
    if r_hndtree.id <> nvl( p_hnd_id,-1)
    then  -- cannot become child of yourself
      htp.p
      ( '<OPTION VALUE="'||to_char(r_hndtree.id)||'"'
      ||cdwpbase.ifThenElse
        ( r_hndtree.id = r_hnd.parent_node
        , 'SELECTED=Y'
        )
      ||'>'
      ||cdwpbase.nbsp(r_hndtree.tree_level*3)
      ||'-'
      ||to_char( r_hndtree.seq_in_parent)
      ||'.'
      ||r_hndtree.display_label
      ||cdwpbase.ifThenElse
        ( r_hndtree.him_id is not null
        , ' (help item id='||to_char(r_hndtree.him_id)||')'
        )
      );
    end if; -- r_hndtree.id <> nvl( p_hnd_id,-1)
  end loop; -- r_hndtree
  htp.formselectclose;
  htp.p('</TD>');
  cdwp.tableRowClose;
  cdwp.tablerowopen;
  cdwp.tabledataheading(Rob_msg.GetMsg(Rob_msg.DSP244_ODWAHELP_SEQWPAR,'','','',''));
  cdwp.tabledatavalue
  ( htf.formtext
    ( cname => 'p_seq_in_parent'
    , csize => 10
    , cmaxlength => 20
    , cvalue => to_char(r_hnd.seq_in_Parent)
    )
  );
  cdwp.tablerowclose;

  for i in 1..g_htt_table.count loop
    cdwp.tableRowOpen;
    cdwp.TableDataValue
      (  cdwp.p(p_string => 'Help Text',p_style => 'partitle')
      ||'<BR>'
      ||htf.formtextarea2
        ( cname => 'txt'||to_char(i)
        , nrows => 20
        , ncolumns => 80
        , cwrap => 'VIRTUAL'
        )
      , p_Colspan => 2
      );
       cdwp.tableRowClose;
  end loop; -- i
  -- one empty area for an additional block
  cdwp.tableRowOpen;
  cdwp.TableDataValue
    (  cdwp.p(p_string => 'New Help Text',p_style => 'partitle')
    ||'<BR>'
    ||htf.formtextarea2
      ( cname => 'txt'||to_char(g_htt_table.count + 1)
      , nrows => 20
      , ncolumns => 80
      , cwrap => 'VIRTUAL'
      )
    , p_Colspan => 2
    );
     cdwp.tableRowClose;
  htp.tableClose;
  htp.formclose;
  htp.bodyClose;
  htp.htmlClose;
end; -- editHelpItem

function get_new_him_id
return number
is
  cursor c_him_id is
    select max(id) id
    from   odwa_help_items
    ;
  l_him_id number(10);
begin
  open c_him_id;
  fetch c_him_id
  into  l_him_id;
  close  c_him_id;
  return l_him_id + 10;
end; -- get_new_him_id

function get_new_hnd_id
return number
is
  cursor c_hnd_id is
    select odwa_hnd_seq.nextval
    from   dual
    ;
  l_hnd_id number(10);
begin
  open c_hnd_id;
  fetch c_hnd_id
  into  l_hnd_id;
  close  c_hnd_id;
  return l_hnd_id;
end; -- get_new_hnd_id

-- this procedure receives the Form Post with the edited help item and will update the database tables
-- subsequently, it will display the help item in the current document (frame) using helpItemFrame
procedure saveHelpItem
( p_session_id           in number
, p_hnd_id               in   number default null -- the node id ODWA_HELP_NODES table
, him_id                 in number default null
, p_description          in varchar2
, p_document             in varchar2 default null
, p_keywords             in varchar2 default null
, p_parent_node          in number   default null
, p_seq_in_parent        in number   default null
, txt1                   in varchar2 default null
, txt2                   in varchar2 default null
, txt3                   in varchar2 default null
, txt4                   in varchar2 default null
, txt5                   in varchar2 default null
, txt6                   in varchar2 default null
, txt7                   in varchar2 default null
, txt8                   in varchar2 default null
) is
  l_him_id number(10):= him_id;
  l_hnd_id number(10):= p_hnd_id;
  l_parent_node number(10);
  l_ctr number(5);
  l_tree_level number(2);  -- to store the old hnd_tree_level

begin
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'saveHelpItem'
  );
  -- Deal with Help Item first
  if him_id is null
     and
     nvl(nvl( txt1, p_keywords), p_document) is not null
  then  -- only create a real help item if there is something for real
    -- derive him_id
    l_him_id := get_new_him_id;
    -- insert into odwa_help_items
    insert into odwa_help_items him
    ( id, description, document, keywords)
    values
    ( l_him_id
    , p_description
    , p_document
    , p_keywords
    )
    ;
   else
     if l_him_id is not null
     then
      -- update odwa_help_items
      update odwa_help_items
      set    document = p_document
      ,      keywords = p_keywords
      ,      description = p_description
      where  id       = l_him_id
      ;
      delete odwa_help_text where him_id = l_him_id;
    end if; -- him_is is null
  end if; -- him_is is null

  -- now if it is worth the trouble, let's do something about the Help Tree Node
  -- if p_hnd_id is null, the node is new; if p_parent_node is not null, a node should be
  -- created
  if p_hnd_id is null
     and
     p_parent_node is not null
  then
    l_hnd_id:= get_new_hnd_id;
    -- now insert
    insert into odwa_help_nodes hnd
    ( id, parent_node, seq_in_parent, tree_level, display_label, him_id)
    select l_hnd_id
    ,      p_parent_node
    ,      nvl( p_seq_in_parent,1)
    ,      tree_level + 1
    ,      p_description
    ,      l_him_id
    from   odwa_help_nodes
    where  id = p_parent_node
    UNION
    select l_hnd_id
    ,      p_parent_node
    ,      nvl( p_seq_in_parent,1)
    ,      1
    ,      p_description
    ,      l_him_id
    from   dual
    where  0 = p_parent_node
    ;
  else
    -- UPDATE node
    cache_hnd( p_hnd_id);
    l_tree_level := r_hnd.tree_level;

    if p_seq_in_parent <> r_hnd.seq_in_parent
       or
       nvl( p_parent_node ,-1)<> nvl( r_hnd.parent_node,-1)
       or
       p_description <> r_hnd.display_label
    then
      update odwa_help_nodes hnd
      set    tree_level =
            ( select tree_level + 1
              from odwa_help_nodes
              where id = p_parent_node
              UNION
              select 1
              from   dual
              where  p_parent_node = 0
              )
      ,      parent_node = p_parent_node
      ,      seq_in_parent = nvl( p_seq_in_parent,1)
      ,      display_label = p_description
      where  id = p_hnd_id
      ;
      -- update the tree level if necessary
      cache_hnd( p_hnd_id); -- after the update
      if r_hnd.tree_level <> l_tree_level
      then
        for r_hnd_tree in c_hnd_tree( b_parent_node => p_hnd_id) loop
          update odwa_help_nodes
          set    tree_level = tree_level + (r_hnd.tree_level - l_tree_level)
          where  rowid = r_hnd_tree.hnd_rowid
          ;
        end loop; --r_hnd_tree
      end if; -- r_hnd.tree_level <> l_tree_level
    end if; -- p_seq_in_parent <> r_hnd.seq_in_parent  or  nvl( p_parent_node ,-1)<> nvl( r_hnd.parent_node,-1)        p_description <> r_hnd.display_label
  end if;  -- p_hnd_id is null and p_parent_node is not null
  if p_parent_node is not null
     and
     ( p_hnd_id is null
       or
       p_seq_in_parent <> r_hnd.seq_in_parent
     )
  then
     -- make room for the new or relocate node
     update odwa_help_nodes
     set    seq_in_parent = seq_in_parent + 1
     where  seq_in_parent >= p_seq_in_parent
     and    parent_node    = p_parent_node
     and    id            <> l_hnd_id
     ;
    -- neatly number the child nodes
    l_ctr := 1;
    for r_chld in c_hnd_chld
                  ( b_parent_hnd_id => p_parent_node
                  ) loop
       update odwa_help_nodes
       set    seq_in_parent = l_ctr
       where  rowid = r_chld.hnd_rowid
       ;
       l_ctr:= l_ctr + 1;
    end loop; -- r_chld

  end if; --
  if txt1 is not null
  then
    insert into odwa_help_text  (him_id, seq, txt) values ( l_him_id, 5, txt1);
  end if;
  if txt2 is not null
  then
    insert into odwa_help_text  (him_id, seq, txt) values ( l_him_id, 10, txt2);
  end if;
  if txt3 is not null
  then
    insert into odwa_help_text  (him_id, seq, txt) values ( l_him_id, 15, txt3);
  end if;
  if txt4 is not null
  then
    insert into odwa_help_text  (him_id, seq, txt) values ( l_him_id, 20, txt4);
  end if;
  if txt5 is not null
  then
    insert into odwa_help_text  (him_id, seq, txt) values ( l_him_id, 25, txt5);
  end if;
  -- invoke helpitem
  odwahelp.show_help_item
  ( p_session_id => p_session_id
  , p_him_id => l_him_id
  , p_hnd_id  => l_hnd_id
  );
end; -- saveHelpItem

procedure node_selected
( p_session_id             in number
, p_node_value             in varchar2 default null
, p_node_type              in varchar2 default null
, p_root_value             in varchar2
, p_root_classification    in varchar2 default null
) is
  l_type varchar2(30):= cdwpbase.get_tag_value( p_string=> p_node_type, p_tag => 'TYPE');
  l_root_type varchar2(30):= cdwpbase.get_tag_value( p_string=> p_root_classification, p_tag => 'TYPE');
  l_seq    varchar2(30):= cdwpbase.get_tag_value( p_string=> p_node_type, p_tag => 'SEQ') ;
  l_hnd_id varchar2(30):= cdwpbase.get_tag_value( p_string=> p_node_type, p_tag => 'ID') ;

begin
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'nodeSelected'
  );
  if l_hnd_id is not null
  then
    cache_hnd( p_hnd_id => to_number( l_hnd_id));
    show_help_item
    ( p_session_id => odwactxt.get_session_id
    , p_him_id     => r_hnd.him_id
    , p_hnd_id     => l_hnd_id
    );
  else
    show_help_item
    ( p_session_id => odwactxt.get_session_id
    , p_him_id     => to_number( p_node_value)
    );
  end if;
end; -- node_selected

procedure inflate_help_node
( p_type       in varchar2 default null
, p_tree_level in number   default null
, p_seq        in number   default null
, p_hnd_id     in number   default null
) is
  l_icon   varchar2(200);
  l_link   varchar2(2000);

  cursor c_hnd
         ( b_parent_node in number
         ) is
  select hnd.seq_in_parent
  ,      hnd.tree_level
  ,      hnd.display_label
  ,      hnd.him_id
  ,      hnd.parent_node
  ,      hnd.id
  from   odwa_help_nodes hnd
  where  hnd.parent_node  = b_parent_node
  order
  by     hnd.seq_in_parent
  ;

  cursor c_him
  is
  select him.id
  ,      him.document
  ,      him.description
  ,      him.keywords
  from   odwa_help_items him
  order
  by     him.description
  ;
begin

  if p_type='INDEX'
  then
    -- if the number of entries is large, we can insert an additional level, such as A-K, L-Z
    for r_him in c_him loop
     htmltree.add_node
      ( p_display_label    => r_him.description
      , p_node_level       => 2
      , p_has_children     => false
      , p_is_expanded      => false
      , p_value            => to_char(r_him.id)
      , p_additional_label => ''
      , p_is_inflatable    => false
      , p_classification   => ''
      );
     end loop; -- r_him
   else
   /*
      for r_htr in c_htr(b_htr_seq => p_seq) loop
         if r_htr.tree_level <= p_tree_level
         then
           exit;
         end if;
         htmltree.add_node
          ( p_display_label    => r_htr.display_label
          , p_node_level       => r_htr.tree_level
          , p_has_children     => false
          , p_is_expanded      => false
          , p_value            => to_char(r_htr.him_id)
          , p_additional_label => ''
          , p_is_inflatable    => true
          , p_classification   => '{TREE_LEVEL='||to_char(r_htr.tree_level)||'}'
                                ||'{SEQ='||to_char(r_htr.seq)||'}'
          );
      end loop; --r_htr
     */
        for r_hnd in c_hnd( b_parent_node => p_hnd_id) loop
           htmltree.add_node
            ( p_display_label    => r_hnd.display_label
            , p_node_level       => r_hnd.tree_level
            , p_has_children     => false
            , p_is_expanded      => false
            , p_value            => to_char(r_hnd.him_id)
            , p_additional_label => ''
            , p_is_inflatable    => true  -- check ???
            , p_classification   => '{TREE_LEVEL='||to_char(r_hnd.tree_level)||'}'
                                  ||'{SEQ='||to_char(r_hnd.seq_in_parent)||'}'
                                  ||'{ID='||to_char(r_hnd.id)||'}'
            );
         end loop; --r_hnd


   end if; -- p_type='INDEX'
end; -- inflate_help_nodes



procedure inflate_Node
( p_node_index    in number
, p_node_level    in number  -- level of node-to-be-inflated (all its children will have p_node_level + 1 or higher)
                             -- node levels in client are number 0..(highest level-1). in server 1..highest level
, p_num_of_nodes           in number
, p_node_value             in varchar2 default null
, p_node_type              in varchar2 default null
, p_entry_point            in number   default null
, p_session_id             in number
, p_root_value             in varchar2
, p_root_classification    in varchar2 default null
) is
  l_type varchar2(30):= cdwpbase.get_tag_value( p_string=> p_node_type, p_tag => 'TYPE') ;
  l_tree_level varchar2(30):= cdwpbase.get_tag_value( p_string=> p_node_type, p_tag => 'TREE_LEVEL') ;
  l_seq varchar2(30):= cdwpbase.get_tag_value( p_string=> p_node_type, p_tag => 'SEQ') ;
  l_root_type varchar2(30):= cdwpbase.get_tag_value( p_string=> p_root_classification, p_tag => 'TYPE') ;
  l_hnd_id varchar2(30):= cdwpbase.get_tag_value( p_string=> p_node_type, p_tag => 'ID') ;
begin
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'inflate_node'
  );

  htmltree.reset_tbl;
  inflate_help_node( p_type => l_type, p_tree_level => l_tree_level, p_seq => l_seq, p_hnd_id => l_hnd_id);


  htmltree.find_folder_nodes; -- to set the had_children property where appropriate
  htmltree.write_inflate_code
  ( p_node_index    => p_node_index
  , p_num_of_nodes  => p_num_of_nodes
  , p_frame_locator => 'top.'
  , p_entry_point   => p_entry_point
  );
end; -- inflate_node

procedure dataXchange
( p_session_id    in   number
)
is
begin
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'dataXchange'
  );

  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  htp.headClose;
  htp.bodyOpen;
  htp.bodyClose;
  htp.htmlClose;
end; -- dataXchange

procedure rightSide
( p_session_id    in   number
, p_him_id        in   number default null
) is
begin
  -- create session when necessary, refresh session cache, set workarea context
  -- from here on reference to odwactxt.get_... functions for any context value
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'rightSide'
  );

  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  htp.headClose;
  htp.framesetopen
  ( crows       =>  '100%,*'
  , cattributes => 'BORDER="0" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'" LONGDESC=odwahelp.rightSide?p_session_id=&p_him_id=150'
  );
  htp.frame
  ( 'odwahelp.show_help_item?'
  ||'p_him_id='||to_char(p_him_id)
  , cname=> 'helpFrame'
  , cattributes => 'TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'" LONGDESC=odwahelp.rightSide?p_session_id=&p_him_id=150'
  );
  htp.frame
  ( 'odwahelp.dataXchange?p_session_id='
          ||to_char(odwactxt.get_session_id)
  , cname=> 'dataXchange'
  , cscrolling => 'no'
  , cattributes => 'TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'" LONGDESC=odwahelp.rightSide?p_session_id=&p_him_id=150'
  );
  htp.framesetclose;
  htp.htmlClose;
end; -- rightSide

procedure topSide
( p_session_id    in   number
)
is
begin
  -- create session when necessary, refresh session cache, set workarea context
  -- from here on reference to odwactxt.get_... functions for any context value
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'topSide'
  );
  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  htp.headClose;
  htp.bodyopen(cattributes => 'BGCOLOR = #FFFFFF');
  cdwp.tool_header('help');
  htp.bodyClose;
  htp.htmlClose;
end; -- topSide

procedure helpTree
( p_session_id    in   number
)
is
  l_first   boolean;
begin
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'navigatorTree'
  );

  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  htp.headClose;
  --
  -- body
  --
  htp.bodyOpen
  ( cattributes=>'BGCOLOR="#FFFFFF" '
  ||'onLoad="top.init();top.drawOnLoad()"'
  );
  htp.p(Rob_msg.GetMsg(Rob_msg.DSP245_ODWAHELP_WAITMSG,'','','',''));
  htp.bodyClose;
  htp.htmlClose;
end; -- helpTree


procedure load_help_tree
is
  l_icon   varchar2(200);
  l_link   varchar2(2000);

  cursor c_him
  is
  select him.id
  ,      him.document
  ,      him.description
  ,      him.keywords
  from   odwa_help_items him
  order
  by     him.description
  ;
  cursor c_hnd
  is
  select hnd.seq_in_parent
  ,      hnd.tree_level
  ,      hnd.display_label
  ,      hnd.him_id
  ,      hnd.parent_node
  ,      hnd.id
  from   odwa_help_nodes hnd
  where  hnd.tree_level = 1 -- root_nodes
  order
  by     hnd.seq_in_parent
  ;

begin
  htmltree.reset_tbl;
  for r_hnd in c_hnd loop
   htmltree.add_node
    ( p_display_label    => r_hnd.display_label
    , p_node_level       => r_hnd.tree_level
    , p_has_children     => true
    , p_is_expanded      => false
    , p_value            => to_char(r_hnd.him_id)
    , p_additional_label => ''
    , p_is_inflatable    => true
    , p_classification   => '{TREE_LEVEL='||to_char(r_hnd.tree_level)||'}'
                          ||'{SEQ='||to_char(r_hnd.seq_in_parent)||'}'
                          ||'{ID='||to_char(r_hnd.id)||'}'
    );
  end loop; --r_hnd

  -- add node Table of Contents with all help topics as children
   htmltree.add_node
    ( p_display_label    => Rob_Msg.Getmsg(Rob_msg.CAP113_ODWAGRPH_IDX,'','','','')
    , p_node_level       => 1
    , p_has_children     => true
    , p_is_expanded      => false
    , p_value            => ''
    , p_additional_label => ''
    , p_is_inflatable    => true
    , p_classification   => 'nolink;{TYPE=INDEX}'
    );
   htmltree.find_folder_nodes; -- to set the has_children property where appropriate
end; -- load_help_tree

-- main procedure for the select WA and Folder screen
-- sets up a frame that ultimately will look as follows:
-- -------------------------------
-- |                             |
-- |                             |
-- |              |              |
-- | helpTree     | helpFrame    |
-- |              |------------- |
-- |              | dataXchange  |
-- -------------------------------
--                  { rightSide }

-- this procedure renders the ODWA On line help system, consisting of a tree with all topics
-- and a display panel for the current topic
procedure odwa_help
( p_session_id in number default null
, p_him_id        in   number default null
) is
  l_js_action varchar2(2000);
  l_node_href varchar2(2000);
begin
  -- create session when necessary, refresh session cache, set workarea context
  -- from here on reference to odwactxt.get_... functions for any context value
  odwactxt.update_context
  ( p_session_id    => p_session_id
  , p_package_name  => PACKAGE_NAME
  , p_procedure_name=> 'odwa_help'
  );

  htp.htmlOpen;
  htp.headOpen;
  l_js_action:=
  'function pickNode( idx)
    {
    selectedIdx = idx;
    redrawTree();
    top.rightSide.helpFrame.location = "odwahelp.node_selected?p_session_id='||to_char(odwactxt.get_session_id)
    ||chr(38)||'p_node_value="+nodesTree[idx].value+"'
    ||chr(38)||'p_node_type="+nodesTree[idx].classification+"'
    ||chr(38)||'p_root_value="+nodesTree[getParentNodeAbsolute( idx, 1)].value+"'
    ||chr(38)||'p_root_classification="+nodesTree[getParentNodeAbsolute( idx, 1)].classification
    ;
    } // pickNode
  ';

  l_node_href:=
  'pickNode(\"" +idx + "\" )';
  htp.htmlOpen;
  htp.headOpen;
  cdwp.write_about(package_name, revision_label);
  cdwp.include_report_styles;
  odwahelp.js_invoke_help;
  -- if the workarea context has been set
  -- then we can build the tree and its data in this Frame
    load_help_tree;
    htmltree.js_tree
    ( p_codeFrameName      => 'top'
    , p_treeFrameName      => 'helpTree'
    , p_treeFramePath      => 'top.helpTree'
    , p_xchangeFramePath   => 'top.rightSide.dataXchange'
    , p_js_action          => l_js_action
    , p_node_href          => l_node_href
    , p_inflate_request    => 'odwahelp.inflate_Node'
    , p_inflate_parameters =>   '"'
                              ||chr(38)
                              ||'p_session_id='||to_char(odwactxt.get_session_id)
                              ||chr(38)
                              ||'p_root_value="+nodesTree[getParentNodeAbsolute( idx, 1)].value'
                              ||'+"'
                              ||chr(38)
                              ||'p_root_classification="+nodesTree[getParentNodeAbsolute( idx, 1)].classification'
    );



  cdwp.write_about(package_name, revision_label);
  htp.title('ROB On Line Help');
  htp.headClose;
  htp.framesetopen
  ( crows  => '130,*'
  , cattributes => 'BORDER=0 FRAMEBORDER=0 LONGDESC="" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'"'
  );
  htp.frame
  ( csrc        => 'odwahelp.topSide?p_session_id='
                   ||to_char(odwactxt.get_session_id)
  , cname       => 'topSide'
  , cattributes => 'SCROLLING=NO LONGDESC="" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'"'
  );
  htp.framesetopen
  ( ccols       =>  '30%,70%'
  , cattributes => 'BORDER="2" LONGDESC="" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'"'
  );
  htp.frame
  ( csrc => 'odwahelp.helpTree?p_session_id='
          ||to_char(odwactxt.get_session_id)
  , cname=> 'helpTree'
  , cattributes=>'LONGDESC="" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'"'
  );

  htp.frame
  ( 'odwahelp.rightSide?p_session_id='
          ||to_char(odwactxt.get_session_id)
  ||chr(38)||'p_him_id='||to_char(p_him_id)
  , cname=> 'rightSide'
  , cattributes=> 'LONGDESC="" TITLE="'
     ||Rob_msg.Getmsg(rob_msg.DSP104_CDWP_HELP,'','','','')||'"'
  );
  htp.framesetclose;
  htp.framesetclose;
  htp.htmlClose;
end;  -- odwa_help


begin
  g_odwa_doc_path   := odwapref.get_value(p_preference_name => 'doc_path');
  g_allow_help_edit := odwapref.get_value(p_preference_name => 'edit_help_allowed')= 'Y';
end; -- odwahelp
/