PROMPT Creating Trigger 'BS_MGMP_KOMITENTI'
CREATE OR REPLACE TRIGGER BS_MGMP_KOMITENTI
 BEFORE DELETE OR INSERT OR UPDATE
 ON MGMP_KOMITENTI
BEGIN
   replikacija.brisi_tab;
END;
/
SHOW ERROR


PROMPT Creating Trigger 'AR_MGMP_KOMITENTI'
CREATE OR REPLACE TRIGGER AR_MGMP_KOMITENTI
 AFTER DELETE OR INSERT OR UPDATE
 ON MGMP_KOMITENTI
 FOR EACH ROW
BEGIN
   replikacija.napuni_tab (:OLD.id, :NEW.id);
END;
/
SHOW ERROR


PROMPT Creating Trigger 'BUR_MGMP_KOMITENTI'
CREATE OR REPLACE TRIGGER BUR_MGMP_KOMITENTI
 BEFORE UPDATE
 ON MGMP_KOMITENTI
 FOR EACH ROW
DECLARE

  br_redaka_l NUMBER;
BEGIN
  pra_zmp_zaj.oblikuj_podatak ('SIFRA', 'MGMP_KOMITENTI', :NEW.sifra);

  :NEW.dat_valjan := TRUNC (:NEW.dat_valjan);
  :NEW.dat_ponisten := TRUNC (:NEW.dat_ponisten);

  pra_zmp.provjeri_regiju (:NEW.reg_id, :NEW.zem_id);
  pra_zmp.provjeri_postu (:NEW.pos_id, :NEW.zem_id);

  -- Ažuriraj agenciju (samo na centru)
  IF pra_zmp_zaj.centar = -1
    /*
    ZMP parametar 0030: Kod promjene podataka u komitentu automatski promijeniti
    odgovarajuće podatke u agenciji koja je vezana za tog komitenta.
    */
    AND UPPER (SUBSTR (pra_zmp_zaj.vrijednost_parametra ('0030'), 1, 1)) = 'D'
  THEN
    SELECT COUNT (1) INTO br_redaka_l
      FROM m_agencije
     WHERE gmpkom_id = :OLD.id;
    IF br_redaka_l > 0 THEN
      UPDATE m_agencije
         SET vpobv_id = :NEW.vpobv_id,
             gkage_id = :NEW.gkage_id,
             pos_id = :NEW.pos_id,
             reg_id = :NEW.reg_id,
             zem_id = :NEW.zem_id,
             ban_id = :NEW.ban_id,
             stpla_id = :NEW.stpla_id,
             sifra = :NEW.sifra,
             naziv = :NEW.naziv,
             naz_dodatni = :NEW.naz_dodatni,
             oib = :NEW.oib,
             br_porezni = :NEW.br_porezni,
             br_racuna = :NEW.br_racuna,
             iban = :NEW.iban,
             naz_ulice = :NEW.naz_ulice,
             imep_osobeodg = :NEW.imep_osobeodg,
             br_telefona = :NEW.br_telefona,
             br_telefaksa = :NEW.br_telefaksa,
             email = :NEW.email,
             www = :NEW.www,
             dat_valjan = :NEW.dat_valjan,
             dat_ponisten = :NEW.dat_ponisten,
             ozn_uputnica = :NEW.ozn_uputnica,
             ozn_glavni_racun = :NEW.ozn_glavni_racun,
             sifra_pj = :NEW.sifra_pj
       WHERE gmpkom_id = :OLD.id;
    END IF;
  END IF;
  -- KRAJ Ažuriraj agenciju

  pra_zmp_zaj.upisi_audit (:NEW.unos_korisnik, :NEW.unos_dat, :NEW.izmjena_korisnik, :NEW.izmjena_dat);
END;
/
SHOW ERROR


PROMPT Creating Trigger 'BIR_MGMP_KOMITENTI'
CREATE OR REPLACE TRIGGER BIR_MGMP_KOMITENTI
 BEFORE INSERT
 ON MGMP_KOMITENTI
 FOR EACH ROW
BEGIN
  -- IRN 2888
  IF SYS_CONTEXT ('LOGINFO_CTX', 'SSOUSER') = 'ITNEW'
    AND SYS_CONTEXT ('LOGINFO_CTX', 'VLASNIKPODATKA') = pra_zmp_zaj.vrijednost_parametra ('0999')
  THEN
    RETURN;  -- izlaz iz trigera
  END IF;

  :NEW.id := pra_zmp_zaj.sekvenca (:NEW.id);

  pra_zmp_zaj.oblikuj_podatak ('SIFRA', 'MGMP_KOMITENTI', :NEW.sifra);

  IF :NEW.dat_valjan IS NULL THEN
    :NEW.dat_valjan := TRUNC (SYSDATE, 'RRRR');
  END IF;
  :NEW.dat_valjan := TRUNC (:NEW.dat_valjan);
  :NEW.dat_ponisten := TRUNC (:NEW.dat_ponisten);

  pra_zmp.provjeri_regiju (:NEW.reg_id, :NEW.zem_id);
  pra_zmp.provjeri_postu (:NEW.pos_id, :NEW.zem_id);

  pra_zmp_zaj.upisi_audit (:NEW.unos_korisnik, :NEW.unos_dat, :NEW.izmjena_korisnik, :NEW.izmjena_dat);
END;
/
SHOW ERROR


PROMPT Creating Trigger 'AS_MGMP_KOMITENTI'
CREATE OR REPLACE TRIGGER AS_MGMP_KOMITENTI
 AFTER DELETE OR INSERT OR UPDATE
 ON MGMP_KOMITENTI
BEGIN
   replikacija.azuriraj_retke (
      aplikacija_p => 'ZMP',
      tablica_p    => 'MGMP_KOMITENTI');
END;
/
SHOW ERROR